10  REM PROGRAM NAME = CONDI, CONDITIONAL PROBABILITY
20  DIM A$[3],B$[30]
30  Z1=2
40  PRINT "DO YOU WANT INSTRUCTIONS FOR RUNNING CONDI  ";
50  INPUT A$
60  IF A$="YES" THEN 100
70  IF A$="NO" THEN 340
80  GOTO 40
90  PRINT "----- DEFINITION:"
100  PRINT "CONDITIONAL PROBABILITY DEALS WITH A REDUCED SAMPLE SPACE."
110  PRINT "   EXAMPLE: TWO 3'S AND TWO 5'S ARE ARRANGED IN SOME ORDER."
120  PRINT "   ALL ARRANGEMENTS ARE EQUALLY LIKELY."
130  PRINT "   IF THE LAST NUMBER IN THE ARRANGEMENT IS A 5,"
140  PRINT "   WHAT IS THE PROBABILITY THAT THE TWO 3'S ARE TOGETHER?"
150  PRINT 
160  PRINT "   SAMPLE SAPCE OF THE POSSIBLE ARRANGEMENTS:"
170  PRINT "   (3,3,5,5), (3,5,3,5), (3,5,5,3), (5,3,5,3), (5,5,3,3), (5,3,3,5)"
180  PRINT 
190  PRINT "   A REDUCED SAMPLE SPACE WITH A 5 AS THE LAST ELEMENT IS"
200  PRINT "   (3,3,5,5), (3,5,3,5), (5,3,3,5)"
210  PRINT 
220  PRINT "   EVENT 'A' IS 'THE TWO E'S ARE TOGETHER'."
230  PRINT "   SINCE THERE ARE TWO SAMPLE POINTS IN 'A',"
240  PRINT "   P(A) = 2/3."
250  PRINT 
260  PRINT "IS THERE AN EQUATION FOR CALCULATING CONDITIONAL PROBABILITIES?"
270  PRINT 
280  PRINT "TRY THE FOLLOWING EXPERIMENT - TOSSING UP TO 5 POLYHEDRA:"
290  PRINT "EVENT 'A' IS 'AT LEAST ONE POLYHEDRON WILL STOP WITH A SIDE"
300  PRINT "DOWN OF YOUR CHOICE'.  EVENT 'B' IS 'THE SUM OF THE DOWN SIDES"
310  PRINT "IS LESS THAN A SUM OF YOUR CHOICE'."
320  PRINT 
330  PRINT "IT WILL BE HELPFUL TO HAVE THE SAMPLE SPACE PRINTED FOR YOU."
340  N5=X5=M[1]=M[2]=M[3]=C8=N6=0
350  PRINT 
360  PRINT 
370  A5=A4=A3=A2=A1=0
380  PRINT "HOW MANY POLYHEDRA DO YOU WANT TO TOSS (MAXIMUM OF 5)";
390  INPUT N1
400  PRINT 
410  IF INT(N1)=N1 AND N1<6 AND N1 >= 1 THEN 440
420  PRINT "YOU HAVE INPUT AN INCORRECT NUMBER OF POLYHEDRA."'10
430  GOTO 380
440  E1=1
450  FOR L2=1 TO 5
460  S[L2]=1
470  NEXT L2
480  PRINT "HOW MANY SIDES FOR EACH POLYHEDRON:"
490  PRINT "TYPE ONE NUMBER AND THE RETURN KEY FOR EACH QUESTION MARK."
500  PRINT 
510  FOR I=1 TO N1
520  INPUT S[I]
530  N6=N6+S[I]
540  IF INT(S[I])=S[I] AND S[I]>1 THEN 570
550  PRINT "YOU HAVE INPUT AN INCORRECT NUMBER OF SIDES FOR YOUR POLYHEDRON."
560  GOTO 480
570  NEXT I
580  PRINT 
590  PRINT "EVENT 'B', THE SUM OF THE DOWN SIDES IS LESS THAN ";
600  INPUT N3
610  IF N3 >= N1 AND N3 <= N6 THEN 640
620  GOSUB 2530
630  GOTO 590
640  PRINT 
650  PRINT "EVENT 'A', AT LEAST ONE POLYHEDRON WILL HAVE THIS SIDE DOWN  ";
660  INPUT N2
670  FOR I=1 TO N1
680  IF N2>0 AND N2 <= S[I] THEN 720
690  NEXT I
700  GOSUB 2530
710  GOTO 650
720  PRINT 
730  PRINT "DO YOU WANT THE SAMPLE SPACE PRINTED";
740  INPUT A$
750  PRINT 
760  IF A$="YES" THEN 800
770  IF A$="NO" THEN 820
780  GOSUB 2070
790  GOTO 730
800  X1=1
810  GOSUB 2100
820  GOSUB 2090
830  P[1]=M[2]/N5
840  P[2]=M[1]/N5
850  P[3]=M[3]/N5
860  IF M[1]=0 THEN 2530
870  P[4]=N5/M[1]*M[3]/N5
880  PRINT "NOW, CALCULATE THE FOLLOWING PROBABILITIES:"
890  PRINT 
900  PRINT "1.P(A)   2.P(B)   3.P(A&B)   4. P(A GIVEN B) "
910  PRINT 
920  FOR L=1 TO 4
930  PRINT L'13TAB(2)".?";
940  A9=240
950  ENTER A9,B9,P
960  IF P <= 1 AND P >= 0 THEN 1000
970  PRINT 
980  PRINT "ALL PROBABILITIES MUST BE BETWEEN 0 AND 1 INCLUSIVE.  TRY AGAIN!"
990  GOTO 930
1000  GOSUB 1890
1010  IF Q=0 THEN 1370
1020  INPUT A$
1030  PRINT 
1040  IF A$="YES" THEN 930
1050  IF A$="NO" THEN 1080
1060  GOSUB 2070
1070  GOSUB 1920
1080  PRINT "DO YOU WANT THE SAMPLE SPACE PRINTED";
1090  INPUT A$
1100  PRINT 
1110  IF A$="NO" THEN 1200
1120  IF A$="YES" THEN 1150
1130  GOSUB 2070
1140  GOTO 1080
1150  X1=1
1160  GOSUB 2100
1170  PRINT "NOW, CALCULATE THE PROBABILITY."
1180  PRINT 
1190  GOTO 930
1200  PRINT "DO YOU WANT THE CORRECT PROBABILITY PRINTED  ";
1210  INPUT A$
1220  PRINT 
1230  IF A$="NO" THEN 2550
1240  IF A$="YES" THEN 1270
1250  GOSUB 2070
1260  GOTO 1200
1270  PRINT "THE CORRECT PROBABILITY IS "P[L]
1280  PRINT 
1290  C8=C8+1
1300  PRINT "DO YOU WANT TO CONTINUE";
1310  INPUT A$
1320  PRINT 
1330  IF A$="YES" THEN 1370
1340  IF A$="NO" THEN 2550
1350  GOSUB 2070
1360  GOTO 1300
1370  NEXT L
1380  FOR J=1 TO 3
1390  N=N5
1400  M=M[J]
1410  GOSUB 1990
1420  M[J]=M
1430  N[J]=N
1440  NEXT J
1450  N=N5*M[8]
1460  M=N5*M[9]
1470  GOSUB 1990
1480  M[4]=M
1490  N[4]=N
1500  IF C8>2 THEN 1520
1510  PRINT "YOU CORRECTLY CALCULATED"4-C8" OF THE PROBABILITIES."
1520  PRINT "THE PROBABILITIES COULD HAVE BEEN WRITTEN IN THE FOLLOWING WAY."
1530  PRINT 
1540  PRINT "1. P(A) = "M[2]"/"N[2]
1550  PRINT "2. P(B) = "M[1]"/"N[1]
1560  PRINT "3. P(A&B) = "M[3]"/"N[3]
1570  PRINT "4. P(A GIVEN B) = "M[4]"/"N[4]
1580  PRINT 
1590  PRINT "CAN YOU SEE WHAT THE FORMULA FOR THE PROBABILITY OF 'A' GIVEN 'B'"
1600  PRINT "WOULD BE USING SOME COMBINATION OF P(A&B) AND P(B)";
1610  INPUT A$
1620  PRINT 
1630  IF A$="YES" THEN 1720
1640  IF A$="NO" THEN 1670
1650  GOSUB 2070
1660  GOTO 1590
1670  PRINT "DO YOU WANT TO TRY ANOTHER EXPERIMENT";
1680  INPUT A$
1690  PRINT 
1700  IF A$="NO" THEN 2550
1710  IF A$="YES" THEN 340
1720  PRINT "COMPLETE THE FOLLOWING:"
1730  PRINT "   P(A GIVEN B) = ";
1740  INPUT B$
1750  IF B$="P(A&B)/P(B)" THEN 1840
1760  IF B$="P(B&A)/P(B)" THEN 1840
1770  PRINT "NOT QUITE! DO YOU WANT TO TRY AGAIN";
1780  INPUT A$
1790  PRINT 
1800  IF A$="YES" THEN 1720
1810  IF A$="NO" THEN 1670
1820  GOSUB 2070
1830  GOTO 1720
1840  PRINT 
1850  PRINT "THAT IS THE FORMULA FOR CONDITIONAL PROBABILITY!"
1860  PRINT "DEFINITION -- THE CONDITIONAL PROBABILITY OF AN EVENT A, GIVEN B,""IS DEFINED BY P(A GIVEN B) = P(A&B)/P(B)"
1870  PRINT "IS DEFINED BY THE EQUATION  P(A GIVEN B)=P(A&B)/P(B), IF P(B)#0."
1880  GOTO 2570
1890  IF ABS(P-P[L])<.001 THEN 1950
1900  PRINT 
1910  PRINT 
1920  PRINT "THAT IS NOT CORRECT.  DO YOU WANT TO TRY AGAIN  ";
1930  Q=1
1940  GOTO 1980
1950  Q=0
1960  PRINT '13;TAB(12);"CORRECT!"
1970  PRINT 
1980  RETURN 
1990  FOR K=2 TO M
2000  IF M/K=INT(M/K) AND N/K=INT(N/K) THEN 2020
2010  GOTO 2050
2020  M=M/K
2030  N=N/K
2040  GOTO 2000
2050  NEXT K
2060  RETURN 
2070  PRINT "YOU HAVE MADE A TYPING MISTAKE.  TRY AGAIN!"
2080  RETURN 
2090  X1=N5=0
2100  U7=0
2110  GOTO N1 OF 2160,2150,2140,2130,2120
2120  FOR A5=1 TO S[L2-1]
2130  FOR A4=1 TO S[L2-2]
2140  FOR A3=1 TO S[L2-3]
2150  FOR A2=1 TO S[L2-4]
2160  FOR A1=1 TO S[L2-5]
2170  IF X1=0 THEN 2260
2180  U7=U7+1
2190  GOTO N1 OF 2240,2230,2220,2210,2200
2200  PRINT A5;
2210  PRINT A4;
2220  PRINT A3;
2230  PRINT A2;
2240  PRINT A1
2250  GOTO 2360
2260  N5=N5+1
2270  A9=A1+A2+A3+A4+A5
2280  IF A9 >= N3 THEN 2300
2290  M[1]=M[1]+1
2300  IF A1=N2 OR A2=N2 OR A3=N2 OR A4=N2 OR A5=N2 THEN 2320
2310  GOTO 2430
2320  M[2]=M[2]+1
2330  IF A9 >= N3 THEN 2430
2340  M[3]=M[3]+1
2350  GOTO 2430
2360  IF U7/10#INT(U7/10) THEN 2430
2370  PRINT "DO YOU WANT MORE OF THE SAMPLE SPACE  ";
2380  INPUT A$
2390  IF A$="YES" THEN 2430
2400  IF A$="NO" THEN 2510
2410  GOSUB 2070
2420  GOTO 2360
2430  NEXT A1
2440  NEXT A2
2450  NEXT A3
2460  NEXT A4
2470  NEXT A5
2480  IF X1=1 THEN 2510
2490  M[8]=M[1]
2500  M[9]=M[3]
2510  PRINT 
2520  RETURN 
2530  PRINT '10"YOU HAVE INPUT AN INCORRECT VALUE FOR YOUR EVENT.  CHECK THE NUMBER""OF POLYHEDRA YOU ARE THROWING AND THE NUMBER OF SIDES."'10
2540  RETURN 
2550  PRINT "SINCE YOU DID NOT GET THE CORRECT RELATIONSHIP."
2560  PRINT "ANALYZE YOUR DATA AND TRY AGAIN."
2570  END 
