1  REM ****  HP BASIC PROGRAM LIBRARY  ******************************
2  REM
3  REM       GSPMG: STANFORD PORTFOLIO MANAGEMENT GAME
4  REM       GPMS5, PART 7 OF 7 (OBTAINS SUMMARY OF TEAM'S HOLDINGS)
5  REM       36502 REV A
6  REM
7  REM ****  CONTRIBUTED PROGRAM  ***********************************
50  FILES *SPRDIV,*
55  X$="ABCDEFGHIJKLMNOPQRSTUVWXYZ "
60  DIM F$[5],M$[6]
61  F$="ACCTS"
70  PRINT "CODE FOR FILE";
71  INPUT M$
72  ASSIGN F$,2,R9,M$
100  DIM X$[27],A$[72],T[260]
110  DIM L[260],S[260]
140  READ #1;T3,T2,T1,T0
150  READ #1;N
160  FOR I=1 TO N
165  READ #1;T[I],X,X,X
170  NEXT I
200  PRINT "NUMBER OF TEAMS";
201  INPUT T9
210  FOR I=1 TO N
212  L[I]=S[I]=0
214  NEXT I
216  FOR J=1 TO T9
218  READ #2,(2*J)-1
220  READ #2;A$,X,X,X,X,X
230  FOR I=1 TO N
232  READ #2;H9
234  IF H9>0 THEN 242
236  IF H9=0 THEN 250
238  S[I]=S[I]+ABS(H9)
240  GOTO 250
242  L[I]=L[I]+H9
250  NEXT I
260  NEXT J
300  REM -- PRINT RESULTS
301  PRINT LIN(2)
302  PRINT "SECURITY  LONG  SHORT"
304  PRINT "--------  ----  -----"
310  FOR I=1 TO N
312  A9=T[I]
314  GOSUB 600
315  IF L[I]=0 AND S[I]=0 THEN 330
316  PRINT  USING 320;A$,L[I],S[I]
320  IMAGE 2X,4A,7D,7D
330  NEXT I
350  STOP 
500  REM ------------------------
501  REM -- CONVERT SYMBOL IN A$ TO NUMBER IN A9
510  A$[LEN(A$)+1]="    "
512  A$=A$[1,4]
520  A9=0
530  FOR K=1 TO 4
540  FOR L=1 TO 27
542  IF A$[K,K]=X$[L,L] THEN 550
544  NEXT L
546  L=27
550  A9=(A9*30)+L
560  NEXT K
570  RETURN 
600  REM ------------------------
601  REM -- CONVERT SYMBOL IN A9 TO A$
610  A1=INT(A9/(30^3))
612  A8=A9-(30^3)*A1
614  A2=INT(A8/(30^2))
616  A8=A8-A2*(30^2)
618  A3=INT(A8/30)
620  A4=A8-A3*30
625  A$="    "
630  A$[1,1]=X$[A1,A1]
632  A$[2,2]=X$[A2,A2]
634  A$[3,3]=X$[A3,A3]
636  A$[4,4]=X$[A4,A4]
650  RETURN 
9999  END 
