1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        GRAD:  COLLEGE REGISTRATION DEMO
4  REM
5  REM        36282 REV  A  PART 8 OF 10   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
10  FILES STUDNT,COURSE,WORK1,WORK2
20  DIM O$[2],P$[20],Q$[20],R$[20]
30  DIM A$[12],B$[20],C$[20],D$[2],J$[10],K$[2],M$[2]
35  DIM E$[2],T$[2],U$[2]
36  DIM L$[2]
40  DIM N$[10]
45  DIM F$[12],H$[20]
50  PRINT "ENTER COURSE TITLE";
60  INPUT Z$
70  PRINT "ENTER SECTION#";
80  INPUT E$
90  PRINT "MID-TERM OR FINAL (M OR F)";
100  INPUT V$
110  GOSUB 9200
120  IF Z#0 THEN 150
130  PRINT "COURSE NON EXISTANT"
140  STOP 
150  READ #2;N$,N3,N4
160  Z=Z+1
165  IF N4=0 THEN 220
170  FOR I=1 TO N4
180  READ #2,Z;O$
190  IF O$=E$ THEN 240
200  Z=Z+2
210  NEXT I
220  PRINT "SECTION NON EXISTANT"
230  STOP 
240  READ #2;P$,Q$,R$,N5,N6
245  IF N6=0 THEN 280
246  FOR L=1 TO N6
250  READ #2;X$,T$,U$
260  GOSUB 9000
270  IF X#0 THEN 300
280  PRINT "STUDENT NOT IN FILE"
290  STOP 
300  READ #1;A$,B$,C$
310  PRINT "ENTER MARK FOR ";C$;" ";B$;
320  INPUT D$
330  X=X+2
340  READ #1,X;N1
345  IF N1=0 THEN 400
350  FOR I=1 TO N1
360  READ #1;J$,K$,L$,M$,N2
370  IF J$=Z$ THEN 420
380  PRINT #4;J$,K$,L$,M$,N2, END 
390  NEXT I
400  PRINT "COURSE NOT IN STUDENT FILE"
410  STOP 
420  I9=I
425  IF V$="F" THEN 460
430  L$=D$
440  T$=D$
450  GOTO 480
460  M$=D$
470  U$=D$
480  PRINT #4;J$,K$,L$,M$,N2, END 
490  PRINT #3;X$,T$,U$, END 
500  FOR I=1 TO N1-I9
510  READ #1;J$,K$,L$,M$,N2
520  PRINT #4;J$,K$,L$,M$,N2, END 
530  NEXT I
540  READ #4,1
550  READ #1,X
560  PRINT #1;N1, END 
570  FOR I=1 TO N1
580  READ #4;J$,K$,L$,M$,N2
590  PRINT #1;J$,K$,L$,M$,N2, END 
600  NEXT I
610  NEXT L
620  READ #3,1
630  READ #2,Z
635  PRINT #2;O$,P$,Q$,R$,N5,N6, END 
640  FOR I=1 TO N6
650  READ #3;X$,T$,U$
660  PRINT #2;X$,T$,U$, END 
670  NEXT I
680  STOP 
690  END 
9000  REM GET STUDENT OR COURSE FILE. 
9030  DIM W$[20],X$[12],Y$[20],Z$[10]
9031  IF  END #1 THEN 9038
9032  X1=1
9033  FOR X2=1 TO 32
9034  READ #1,X1;W$
9035  IF W$=X$ THEN 9040
9036  X1=X1+4
9037  NEXT X2
9038  X=0
9039  RETURN 
9040  READ #1,X1
9045  X=X1
9046  RETURN 
9200  IF  END #2 THEN 9207
9201  X1=1
9202  FOR X2=1 TO 9
9203  READ #2,X1;W$
9204  IF W$=Z$ THEN 9209
9205  X1=X1+13
9206  NEXT X2
9207  Z=0
9208  RETURN 
9209  READ #2,X1
9210  Z=X1
9211  RETURN 
9212  END 
