1  REM  NIK1 COMPUTER PROGRAM TO ACCOMPANY NIKOLL ELECTRONICS (A) 7/23/73
2  REM  CASE1: CASES IN COMPUTER AND MODEL ASSISTED MARKETING: PLANNING
3  REM  36790 REV A, 2/74   NIK1, PART 2 OF 5
10  DIM Z$[72]
100  A1=.278393
110  A2=.230389
120  A3=.000972
130  A4=.078108
140  PRINT "COMP BID(MIN,MAX) ";
150  INPUT A,B
160  PRINT "COST,INTANG IF WE LOSE";
170  INPUT C1,I1
180  PRINT "STARTING,ENDING PRICES,STEP ";
190  INPUT P1,P2,P3
200  PRINT "COMPETITIVE (NON-PRICE) ADVANTAGE,MIN,MAX ";
210  INPUT Y1,Y2
212  M2=(Y1+Y2)/2
214  S2=(Y2-Y1)/4
220  M1=(A+B)/2
230  S1=(B-A)/4
235  M3=M1+M2
236  S3=SQR(S1*S1+S2*S2)
240  PRINT 
250  PRINT "PRICE","PROB.WIN","EXP.PROF","EXP.INTAN","EXP.BENE"
260  FOR P=P1 TO P2 STEP P3
270  Z=(P-M3)/S3
280  X=ABS(Z)/SQR(2)
290  U=1+X*(A1+X*(A2+X*(A3+X*A4)))
300  U=U^4
310  U=1-1/U
320  U=U/2
330  Q=.5+SGN(Z)*U
340  Q=1-Q
350  X1=114*(P-C1)*Q
360  X2=-I1*(1-Q)
370  PRINT P,Q,X1,X2,X1+X2
380  NEXT P
390  PRINT 
400  PRINT 
410  PRINT "MORE PRECISION ";
420  INPUT Z$
430  IF Z$[1,1]="N" THEN 470
440  PRINT "STARTING,ENDING PRICES,STEP ";
450  INPUT P1,P2,P3
460  GOTO 240
470  PRINT "ANOTHER BID ";
480  INPUT Z$
490  IF Z$[1,1]="Y" THEN 140
500  END 
