10  COM N1,N2,N3
20  REM *****CORS VERSION 2,  AUGUST 26,1971
30  REM *****TRANSLATED FROM 'FORTRAN PROGRAMMING FOR THE BEHAVIORAL
40  REM *****SCIENCES' BY D.J. VELDMAN
50  PRINT "HOW MANY SUBJECTS ARE THERE";
60  INPUT N1
70  PRINT "HOW MANY VARIABLES ARE THERE";
80  INPUT N2
90  PRINT "MAXIMUM NUMBER OF FACTORS";
100  INPUT N3
110  FILES CORR
120  PRINT "YOU HAVE NOT ENTERED THE FILES STATEMENT"
130  DIM R[64],A[64],S[64],P[64]
140  MAT R=ZER[N2]
150  MAT A=ZER[N2]
160  MAT S=ZER[N2]
170  MAT P=ZER[N2]
180  FOR K=1 TO N2
190  READ #1,2*K-1
200  MAT  PRINT #1;R
210  NEXT K
220  T=1/N1
230  FOR K=1 TO N1
240  F=INT((K*2-1)/128)+2
250  I7=K-64*(F-2)
260  READ #F,I7*2-1
270  MAT  READ #F;S[N2]
280  FOR I=1 TO N2
290  A[I]=A[I]+S[I]
300  I2=I*2-1
310  READ #1,I2
320  MAT  READ #1;R[N2]
330  FOR J=1 TO N2
340  LET R[J]=R[J]+S[I]*S[J]
350  NEXT J
360  READ #1,I2
370  MAT  PRINT #1;R
380  NEXT I
390  NEXT K
400  REM
410  FOR I=1 TO N2
420  I2=2*I-1
430  READ #1,I2
440  MAT  READ #1;R[N2]
450  A[I]=A[I]*T
460  S[I]=SQR((R[I]/N1)-A[I]^2)
470  NEXT I
480  FOR I=1 TO N2
490  I2=2*I-1
500  READ #1,I2
510  MAT  READ #1;R[N2]
520  FOR J=1 TO N2
530  R[J]=(R[J]/N1-A[I]*A[J])/(S[I]*S[J])
540  NEXT J
550  R[I]=1
560  READ #1,I2
570  MAT  PRINT #1;R
580  NEXT I
590  REM
600  PRINT "MEANS"
610  PRINT 
620  MAT P=A
630  GOSUB 920
640  PRINT 
650  PRINT 
660  PRINT "SIGMAS"
670  FOR I2=1 TO N2
680  S[I2]=.0001*INT(10000*S[I2]+.5)
690  NEXT I2
700  PRINT 
710  MAT P=S
720  GOSUB 920
730  PRINT 
740  PRINT 
750  PRINT "CORRELATION MATRIX"
760  PRINT 
770  FOR I=1 TO N2
780  I2=2*I-1
790  READ #1,I2
800  MAT  READ #1;R[N2]
810  FOR I2=1 TO N2
820  R[I2]=.0001*INT(10000*R[I2]+.5)
830  NEXT I2
840  MAT P=R
850  GOSUB 920
860  PRINT 
870  NEXT I
880  PRINT 
890  PRINT 
900  CHAIN "$SEVS"
910  STOP 
920  REM ARRAY PRINT SUBROUTINE
930  FOR I9=1 TO N2
940  PRINT P[I9],
950  NEXT I9
960  PRINT 
970  RETURN 
980  END 
