10  COM T5,V3,A,N,M1,T1,V1,V2,A1,A2,M2,D$[30],N5
20  COM Y$[30]
30  REM PROGRAM NAME = ZOOM, THE PILOTING OF THE MACHINE
40  REM CHAINED TO ZOOMIE, ZTRANS, ZOOMA
50  PRINT '10'10
60  PRINT "THE ENGINES OF YOUR TRANSPORT MACHINE ARE IGNITED."
70  LET T5=V3=A=M2=0
80  B=100
90  N=G1=1
100  M2=0
110  D1=M1
120  DIM A$[10]
130  DIM F[100],G[100],H[100],I[100]
140  PRINT '10"-----PHASE"G1'10
150  G1=G1+1
160  PRINT "DO YOU WANT TO 1) ACCELERATE, OR 2) MAINTAIN VELOCITY?  ";
170  ENTER B,C,Q
180  PRINT '13
190  IF C<0 THEN 210
200  GOTO Q OF 230,430
210  PRINT '10"     INPUT EITHER 1 OR 2.  ";
220  GOTO 170
230  I[N]=T1-T5
240  PRINT "WHAT VALUE OF ACCELERATION (M/SEC/SEC) DO YOU WANT?  ";
250  ENTER B,C,A
260  PRINT '13
270  LET N4=1
280  IF A>A1 THEN 680
290  PRINT 
300  GOSUB 570
310  IF V3^2 >= -2*A*D1 THEN 340
320  T8=-V3/A
330  GOTO 350
340  T8=(-V3+(SQR((V3^2)+2*A*D1)))/A
350  IF T <= T8 THEN 370
360  T=T8
370  LET M=V3*T+.5*A*(T)^2
380  LET V=A*T
390  T5=T5+T
400  GOSUB 890
410  PRINT '10"ACCELERATION FOR"J3"SECONDS."
420  GOTO 820
430  REM CONSTANT VELOCITY 
440  IF V3>V2 THEN 750
450  IF V3<V1 THEN 790
460  PRINT 
470  GOSUB 570
480  T8=D1/V3
490  IF T <= T8 THEN 510
500  T=T8
510  LET M=V3*T
520  LET V=0
530  T5=T5+T
540  GOSUB 890
550  PRINT '10"MAINTAINED VELOCITY OF"V3"M/SEC FOR"J3"SECONDS."
560  GOTO 820
570  PRINT "TIME (WITH RETURN KEY):";
580  LET J2=250
590  ENTER #J1,J2,J3,A$
600  ENTER #J1,J2,J3,A$
610  LET T=J3
620  RETURN 
630  PRINT 
640  PRINT "YOU HAVE EXCEEDED THE MAXIMUM TIME PERMITTED."
650  PRINT "YOUR FUEL SUPPLY IS EXHAUSTED."
660  PRINT "YOU ARE STRANDED AND IN DANGER."
670  GOTO 1040
680  PRINT "------DANGER"'7'7'7'7'7'7'7"----YOU ARE ACCELERATING AT AN EXCESSIVE"
690  PRINT "RATE. YOU HAVE 5 SECONDS TO CHANGE YOUR ACCELERATION."
700  LET K2=5
710  ENTER #K1,K2,K3,A
720  PRINT '13
730  IF K3<0 THEN 70
740  GOTO 280
750  REM MAXIMUM VELOCITY MESSAGE.
760  PRINT '10"DISINTEGRATION VELOCITY HAS BEEN EXCEEDED."
770  PRINT "---------DANGER--DANGER"'7'7'7'7'7'7'7'7"--------"
780  GOTO 1050
790  PRINT '10'10'7'7"YOU HAVE STOPPED YOUR MACHINE BEFORE REACHING THE DESTINATION."
800  PRINT "IT WILL NOT START AGAIN."'7'7
810  GOTO 1090
820  PRINT '10'10"               PRESENT STATE OF TRANSPORT"
830  PRINT "CURRENT","DISTANCE","DISTANCE TO","TIME"
840  PRINT "VELOCITY","TRAVELED","DESTINATION","REMAINING"
850  PRINT "M/SEC","METERS","METERS","SECONDS"
860  PRINT V3,M2,M1-M2,T1-T5
870  D1=M1-M2
880  GOTO 140
890  LET V3=V3+V
900  LET M2=M2+M
910  F[N]=V3
920  G[N]=M2
930  LET H[N]=M1-M2
940  I[N]=T1-T5
950  LET N=N+1
960  IF H[N-1]=0 AND V3>0 THEN 1040
970  IF ABS(M1-M2) >= V2 THEN 990
980  IF ABS(V3)<.5 THEN 1190
990  IF D1=0 AND V3>0 THEN 1040
1000  IF T5>T1 THEN 630
1010  IF V3<V1 OR V3=0 THEN 790
1020  IF V3>V2 THEN 750
1030  RETURN 
1040  PRINT '10"YOU HAVE NOT STOPPED YOUR TRANSPORT MACHINE AT THE DESTINATION"
1050  PRINT ". . . .";
1060  ENTER 3,L3,A$
1070  PRINT ". . . . "'7'7"CRASH, "'7'7'7'7'7"BANG . . ."
1080  ENTER 3,L3,A$
1090  PRINT '10
1100  PRINT "    AUTORECORDER DATA","          PILOT "D$
1110  PRINT "  ","FINAL PHASE","DISTANCE","DISTANCE TO","TIME"
1120  PRINT "PHASE","VELOCITY","TRAVELED","DESTINATION","REMAINING"
1130  PRINT "OF TRIP","M/SEC","METERS","METERS","SECONDS"
1140  FOR X=1 TO N-1
1150  PRINT X,F[X],G[X],H[X],I[X]
1160  NEXT X
1170  END 
1180  GOTO 1040
1190  PRINT '10'7'7'7'7'7'7'7'7'7'7"RIGHT ON!!!!!!"'7'7'7'7'7'7'7'10'10'10'10D$" "'10'10'10"YOU DID IT!!"'7'7'7'7'7'7
1200  PRINT '10'10'10
1210  GOTO 1110
1220  END 
