10  COM T5,V3,A,N,M1,T1,V1,V2,A1,A2,M2,D$[30],N5,Y$[30]
20  GOTO 60
30  CHAIN "$ZOOM"
40  REM PROGRAM NAME = ZOOMA, ADMINISTERS ZOOMIE
50  REM CHAINED TO ZOOMIE, ZOOM, ZTRANS
60  DIM A$[20]
70  B=100
80  K2=250
90  N=1
100  LET T5=V3=A=M2=0
110  IF N5=2 OR N5=3 THEN 460
120  PRINT '10"THIS IS A SIMULATION OF A UNIVERSAL TRANSPORT MACHINE."
130  PRINT "YOU WILL BE A PILOT IN THIS MACHINE AND WILL TRY"
140  PRINT "TO REACH AN ASSIGNED DESTINATION SUCCESSFULLY."
150  PRINT 
160  M1=INT(899999.*RND(1)+10000)
170  M1=INT(M1/1000)
180  M1=M1*1000
190  IF M1/3#INT(M1/3) THEN 160
200  LET F6=M1
210  LET T1=INT(100*RND(1)+10)
220  PRINT Y$", YOU MISSION IS TO TRANSPORT YOURSELF"M1"METERS."
230  PRINT "   THE MAXIMUM TIME ALLOWED IS"T1"SECONDS."
240  PRINT "   YOUR AVERAGE VELOCITY WILL HAVE TO BE"M1/T1"METERS/SECOND."
250  PRINT "   YOUR MISSION NUMBER IS"INT((M1-T1*99)/2)
260  PRINT 
270  PRINT "DO YOU WANT TO DESIGN YOUR MACHINE AWAY FROM THE TELETYPE?  ";
280  ENTER B,C,A$
290  PRINT '13
300  IF A$="YES" THEN 330
310  IF A$#"NO" THEN 270
320  GOTO 460
330  PRINT 
340  PRINT "FOUR DESIGN CHARACTERISTICS YOU MUST CONSIDER ARE THE MACHINE'S:"
350  PRINT "   1. MINIMUM VELOCITY,"
360  PRINT "   2. MAXIMUM VELOCITY,"
370  PRINT "   3. MINIMUM ACCELERATION, AND"
380  PRINT "   4. MAXIMUM ACCELERATION."
390  PRINT 
400  PRINT "YOU SHOULD TRY TO DESIGN A MACHINE THAT IS ADEQUATE TO "
410  PRINT "ACCOMPLISH THE MISSION.  HOWEVER, ANY DESIGN CHARACTERISTICS"
420  PRINT "THAT EXCEED REASONABLE OR NECESSARY DIMENSIONS WILL NOT BE"
430  PRINT "PERMITTED.  WHEN YOU HAVE DETERMINED YOUR DESIGN CHARACTERISTICS,"
440  PRINT Y$", RUN ZOOMIE AGAIN."
450  END 
460  PRINT 
470  LET F6=M1
480  PRINT "YOU ARE NOW GOING TO SPECIFY THE DESIGN CHARACTERISTICS"
490  PRINT "OF YOUR TRANSPORT MACHINE."
500  PRINT 
510  PRINT "INPUT THE MINIMUM VELOCITY(M/SEC) FOR YOUR MACHINE.  ";
520  ENTER B,C,V1
530  PRINT '13
540  IF C<0 THEN 510
550  IF V1 >= 0 THEN 580
560  PRINT "     NEGATIVE VELOCITY IS NOT PERMITTED."
570  GOTO 510
580  PRINT "INPUT THE MAXIMUM VELOCITY(M/SEC) FOR YOUR MACHINE.  ";
590  ENTER B,C,V2
600  PRINT '13
610  IF C<0 THEN 580
620  IF V2<0 THEN 580
630  IF V2 <= 1.5*M1/T1 THEN 740
640  PRINT "     MAXIMUM VELOCITY PERMITTED IS"1.5*M1/T1"METERS/SEC."
650  GOTO 580
660  PRINT "INPUT THE MAXIMUM ACCELERATION(M/SEC/SEC) FOR YOUR MACHINE.  ";
670  ENTER B,C,A1
680  PRINT '13
690  IF C<0 THEN 660
700  IF A1<0 THEN 660
710  IF A1 <= 15*M1/T1^2 THEN 830
720  PRINT "     MAXIMUM ACCELERATION PERMITTED IS"15*M1/T1^2"(M/SEC)/SEC."
730  GOTO 660
740  PRINT "INPUT THE MINIMUM ACCELERATION(M/SEC/SEC) FOR YOUR MACHINE.  ";
750  ENTER B,C,A2
760  PRINT '13
770  IF C<0 THEN 740
780  IF A2<0 THEN 800
790  LET A2=-A2
800  IF -A2 >= -15*M1/T1^2 THEN 660
810  PRINT "     MINIMUM ACCELERATION PERMITTED IS"-15*M1/T1^2"(M/SEC)/SEC."
820  GOTO 740
830  IF N5=3 THEN 30
840  PRINT '10
850  PRINT Y$", YOU WILL BE ABLE TO CONTROL THE AMOUNT OF TIME"
860  PRINT "THAT YOUR MACHINE IS ACCELERATING OR TRAVELING AT A UNIFORM VELOCITY"
870  PRINT "BY USING THE RETURN KEY ON YOUR TELETYPE.  WHEN YOU ARE ASKED FOR THE"
880  PRINT "AMOUNT OF TIME, MEASUREMENT OF THE AMOUNT BEGINS WHEN YOU PRESS THE"
890  PRINT "RETURN KEY, AND STOPS WHEN YOU PRESS IT AGAIN - LIKE A STOP WATCH."
900  PRINT "PLEASE PRACTICE THIS TIMING DEVICE NOW. SEE HOW CLOSE YOU CAN"
910  PRINT "GET TO 5 SECONDS."
920  PRINT 
930  PRINT "TIME (WITH RETURN KEY):";
940  ENTER #K1,K2,K3,A$
950  ENTER #K1,K2,K3,A$
960  PRINT '10;
970  PRINT "TIME USED ="K3"SECONDS.  COMPARE THIS WITH THE TIME"
980  PRINT "YOU THOUGHT YOU HAD USED."
990  PRINT '10
1000  PRINT "USE THE FOLLOWING FORM TO PLAN YOUR MISSION."
1010  PRINT "TRY TO FORSEE ANY POTENTIAL HAZARDS AND PLAN FOR THEM."
1020  PRINT "GOOD LUCK, "Y$
1030  PRINT '10'10'10
1040  LET F7=INT((M1-T1*99)/2)
1050  PRINT "-----MISSION #"F7,"PILOT "D$
1060  PRINT 
1070  PRINT "----- TABLE OF DESIGN CHARACTERISTICS:"
1080  PRINT "V.MIN.","V.MAX.","A.MIN.","A.MAX."
1090  PRINT "M/SEC","M/SEC","(M/SEC)/SEC","(M/SEC)/SEC"
1100  PRINT V1,V2,A2,A1
1110  PRINT 
1120  PRINT "-----   MISSION ASSIGNMENT:"
1130  PRINT "DISTANCE","TIME","AVERAGE VELOCITY"
1140  PRINT "METERS","SECONDS","METERS/SECOND"
1150  PRINT M1,T1,M1/T1
1160  PRINT 
1170  PRINT '10"----- PROJECTED ORDER OF OPERATIONS AND OUTCOMES:"
1180  PRINT "PHASE","ACCELERATION","VELOCITY","TIME"
1190  PRINT "#","(M/SEC)/SEC","M/SEC","SECONDS"
1200  PRINT 
1210  FOR N6=1 TO 8
1220  PRINT 
1230  PRINT N6,"----------","----------","----------"
1240  NEXT N6
1250  PRINT '10'10'10
1260  PRINT "------------------------","--------------------------"
1270  PRINT "       DATE COMPLETED       ","      SIGNATURE        "
1280  PRINT 
1290  PRINT "WHEN YOU HAVE COMPLETED YOUR MISSION PLAN, RUN ZOOMIE AGAIN."
1300  END 
