1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        ANCOV:   ANALYSIS OF COVARIANCE
4  REM
5  REM        36294 REV  A   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
10  PRINT "ANALYSIS OF COVARIANCE";"                NO. GROUPS";
12  REM INSERT DATA AT LINES 400; FIRST X, THEN Y FOR EACH GROUP
15  INPUT G
16  PRINT 
19  LET X2=Y2=C=N=M1=M2=B1=B2=B3=D1=E1=0
20  FOR I=1 TO G
25  PRINT "GROUP  ";I;" NO. OBSERV.";
26  INPUT N[I]
30  LET P2=X[I]=Y[I]=C[I]=0
35  FOR J=1 TO N[I]
40  READ X,Y
45  LET X[I]=X[I]+X
50  LET Y[I]=Y[I]+Y
55  LET C[I]=C[I]+X*Y
60  LET X2=X2+X^2
65  LET Y2=Y2+Y^2
70  LET C=C+X*Y
75  LET P2=P2+X^2
80  NEXT J
85  LET N=N+N[I]
90  LET M1=M1+(X[I])
95  LET M2=M2+Y[I]
100  LET B1=B1+X[I]^2/N[I]
105  LET B2=B2+X[I]*Y[I]/N[I]
110  LET B3=B3+Y[I]^2/N[I]
115  LET E=C[I]-X[I]*Y[I]/N[I]
120  LET D=P2-X[I]^2/N[I]
125  LET D1=D1+D
130  LET E1=E1+E
135  PRINT 
140  NEXT I
145  LET T1=X2-M1^2/N
150  LET B1=B1-M1^2/N
155  LET I1=T1-B1
165  LET T3=Y2-M2^2/N
170  LET B3=B3-M2^2/N
175  LET I3=T3-B3
185  LET T2=C-M1*M2/N
190  LET B2=B2-M1*M2/N
195  LET I2=T2-B2
200  LET A2=T3-T2^2/T1
205  LET A1=I3-I2^2/I1
210  LET A3=A2-A1
218  PRINT 
219  PRINT 
220  PRINT "                 BETWEEN        THIN         TOTAL"
221  PRINT 
225  PRINT "  DF        ",G-1,N-G,N-1
230  PRINT "SUM SQRS X",B1,I1,T1
235  PRINT "SUM  XY   ",B2,I2,T2
240  PRINT "SUM SQRS Y",B3,I3,T3
245  PRINT "ADJ SS Y  ",A3,A1,A2
250  PRINT "ADJ  DF   ",G-1,N-G-1,N-2
255  PRINT "MEAN SQR  ",A3/(G-1),A1/(N-G-1),A2/(N-2)
256  PRINT 
260  PRINT "F         ",(A3/(G-1))/(A1/(N-G-1))
265  LET A=E1/D1
270  PRINT 
271  PRINT 
280  FOR I=1 TO G
285  PRINT "MEAN ADJ Y(";I;")";Y[I]/N[I]-A*(X[I]/N[I]-M1/N)
290  NEXT I
400  DATA 4,6,8,9,14,11
401  DATA 5,5,7,7,12,13,9,12
402  DATA 10,13,8,12,11,16,4,9,7,11
403  DATA 11,11,12,17,8,10,10,13,7,9,10,11
1000  END 
