10  REM *** VERSION OF 4/18/73, JAROSZ***
20  REM HP 36871A, 6/74
100  DIM A[30],S[30],N[30]
110  PRINT "ONE-WAY ANALYSIS OF VARIANCE USING SAMPLE MEANS AND STD. DEVS."
120  PRINT 
130  PRINT 
140  PRINT "DO YOU NEED INSTRUCTIONS (1=YES,0=NO)";
141  INPUT I9
142  IF I9=1 THEN 740
145  LET T=G=H=0
150  PRINT 
160  PRINT "NO. OF GROUPS (30 MAX.)";
170  INPUT N1
180  PRINT 
190  PRINT "FOR EACH GROUP ENTER NO. OF CASES, MEAN, STD. DEV."
200  FOR I=1 TO N1
210  PRINT "GROUP";I;
220  INPUT N[I],A[I],S[I]
340  LET T=T+N[I]
350  LET G=G+A[I]*N[I]
360  NEXT I
370  LET G=G/T
380  LET S1=S2=N2=0
390  FOR I=1 TO N1
400  LET S1=S1+(N[I]-1)*S[I]^2
410  LET S2=S2+N[I]*(A[I]-G)^2
420  LET N2=N2+N[I]-1
430  NEXT I
440  LET N3=N1-1
450  LET N4=N2+N3
460  LET S3=S1+S2
470  LET M1=S1/N2
480  LET M2=S2/N3
490  LET F=M2/M1
590  PRINT 
600  PRINT 
610  PRINT 
620  PRINT TAB(20);"ANALYSIS OF VARIANCE TABLE"
630  PRINT 
640  PRINT " ","S.S.","D.F.","M.S.","F"
650  PRINT 
660  PRINT "BETWEEN",S2,N3,M2,F
670  PRINT 
680  PRINT "WITHIN",S1,N2,M1
690  PRINT 
700  PRINT "TOTAL",S3,N4
710  PRINT 
720  PRINT 
730  PRINT TAB(5);"GRAND MEAN",G
735  GOTO 9999
740  PRINT 
750  PRINT "ALL DATA IS ENTERED WHILE THE PROGRAM IS RUNNING."
760  PRINT "THE PROGRAM WILL ASK FOR NO. OF GROUPS, THEN FOR"
770  PRINT "THE NO. OF CASES, MEAN, AND STD. DEV. FOR EACH GROUP."
780  PRINT "WHEN ALL DATA HAS BEEN ENTERED, THE ANOVA TABLE WILL BE"
790  PRINT "PRINTED."
9999  END 
