1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        FVALUE:   COMPUTES EXACT PROBABILITY OF AN F-RATIO
4  REM                  WITH DEGREES OF FREEDOM (M,N)
5  REM        36720 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
100  REM PROGRAM COMPUTES EXACT PROBABILITY OF AN F-RATIO WITH 
110  REM DEGREES OF FREEDOM (M,N)
120  PRINT "THERE IS A DISCONTINUITY IN THE APPROXIMATION FORMULA USED IN THIS"
130  PRINT "PROGRAM.  HOWEVER, THIS DISCONTINUITY WILL NOT AFFECT VALUES IN"
140  PRINT "THE CRITICAL RANGE."
150  PRINT 
160  PRINT "Enter F-Value, Numerator D. F., and Denominator D. F."
170  INPUT G,M,N
180  LET P=1
190  IF G*M*N=0 THEN 420
200  IF G<1 THEN 250
210  LET A=M
220  LET B=N
230  LET F=G
240  GOTO 280
250  LET A=N
260  LET B=M
270  LET F=1/G
280  LET A1=2/(9*A)
290  LET B1=2/(9*B)
300  LET Z=ABS((1-B1)*F^(.333333)-1+A1)
310  LET Z=Z/SQR(B1*F^(.666667)+A1)
320  IF B<4 THEN 360
330  LET P=(1+Z*(.196854+Z*(.115194+Z*(.000344+Z*.019527))))^4
340  LET P=.5/P
350  GOTO 380
360  LET Z=Z*(1+.08*Z^4/B^3)
370  GOTO 330
380  IF G<1 THEN 400
390  GOTO 440
400  LET P=1-P
410  GOTO 440
420  PRINT "You have erred - Input the 3 values again."
430  GOTO 170
440  PRINT 
450  PRINT 
460  PRINT "Exact Probability of F=";G;"with  ( ";M;",  ";N;")  D.F."
470  PRINT 
480  PRINT "    is ";INT(100000.*P)/100000.
490  END 
