10  REM ***  HP TIME-SHARED BASIC PROGRAM LIBRARY  *********************
11  REM
12  REM         KR20:  ITEM ANALYSIS AND KUDER-RICHARDSON FORMULA 20
13  REM                RELIABILITY
14  REM         36137 (A408) REV A -- 7/71
15  REM
16  REM ***  CONTRIBUTED PROGRAM  **************************************
17  REM
100  REM ITEM ANALYSIS
110  REM K=NO. ITEMS, N=NO. PEOPLE IN EITHER GROUP
120  READ K,N
130  LET S=0
140  PRINT "TEST ITEM","HIGH  LOW   DIFFICULTY       DISCR. INDEX",
150  PRINT "    PQ"
160  LET D1=0
170  LET D2=0
180  FOR I=1 TO K
190  READ H,L
200  PRINT I,H;L;(H+L)/(2*N),(H-L)/N,
210  LET D1=D1+(H+L)/(2*N)
220  LET D2=D2+(H-L)/N
230  LET P=((H+L)/(2*N))*((2*N-H-L)/(2*N))
240  PRINT P
250  LET S=S+P
260  NEXT I
270  REM V=VARIANCE     (S.D.^2)
280  READ V
290  LET R=(K/(K-1))*(1-S/V)
300  PRINT 
310  PRINT "SUM OF PQ="S,"VARIANCE="V
320  PRINT "AVERAGE DIFFICULTY IS "D1/K
330  PRINT "AVERAGE DISCRIMINATION INDEX IS "D2/K
340  PRINT "KUDER-RICHARDSON FORMULA 20 RELIABILITY="R
350  DATA 34,57
360  DATA 44,27,52,42,50,11,49,32,18,2,22,12,56,26,56,29,54,32
370  DATA 56,29,41,13,54,37,57,47,57,36,55,35,55,48,51,27,52,15
380  DATA 50,18,15,8,57,52,53,31,55,40,56,21,55,21,47,14,54,9
390  DATA 45,18,27,11,55,10,48,16,51,22,19,14,22,10
400  DATA 29.963
410  END 
