10  REM ***VERSION OF 4/25/73, JAROSZ***
12  REM HP 36863A, 6/74
100  DIM A[30],S[30],N[30]
110  PRINT "POOLED MEANS AND STANDARD DEVIATIONS"
120  PRINT 
130  PRINT 
140  PRINT "DO YOU NEED INSTRUCTIONS (1=YES,0=NO)";
141  INPUT I9
142  IF I9=1 THEN 740
145  LET T=G=H=0
150  PRINT 
160  PRINT "NO. OF GROUPS (30 MAX.)";
170  INPUT N1
180  PRINT 
190  PRINT "FOR EACH GROUP ENTER NO. OF CASES, MEAN, STD. DEV."
200  FOR I=1 TO N1
210  PRINT "GROUP";I;
220  INPUT N[I],A[I],S[I]
340  LET T=T+N[I]
350  LET G=G+A[I]*N[I]
355  LET H=H+S[I]*S[I]*(N[I]-1)
360  NEXT I
370  LET G=G/T
380  LET H=SQR(H/(T-N1))
390  PRINT 
400  PRINT "TOTAL CASES     ";T
410  PRINT "POOLED MEAN     ";G
420  PRINT "POOLED STD. DEV.";H
735  GOTO 9999
740  PRINT 
750  PRINT "ALL DATA IS ENTERED WHILE THE PROGRAM IS RUNNING."
760  PRINT "THE PROGRAM WILL ASK FOR NO. OF GROUPS, THEN FOR"
770  PRINT "THE NO. OF CASES, MEAN, AND STD. DEV. FOR EACH GROUP."
780  PRINT "WHEN ALL DATA HAS BEEN ENTERED, THE TOTAL NUMBER OF CASES,"
790  PRINT "THE POOLED MEAN, AND THE POOLED STANDARD DEVIATION WILL BE"
800  PRINT "PRINTED."
9999  END 
