1  REM  ****  HP BASIC PROGRAM LIBRARY  ********************************
2  REM
3  REM        STAT07:  CALCULATES THE CONFIDENCE LIMITS FOR A 
4  REM                 SET OF DATA 
5  REM        36725  REV A -- 10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ***************************************
9000  REM  STAT07--WILCOXON SIGNED RANK SUM TEST
9002  DIM D[40],A[820]
9004  PRINT "CONFIDENCE INTERVAL BY SIGNED RANK SUM, FRACTIONAL COUNT"
9006  PRINT 
9008  PRINT "LOWER LIMIT","UPPER LIMIT"
9010  READ N,C
9012  FOR I=1 TO N
9014  READ D[I]
9016  NEXT I
9018  LET K=0
9020  FOR I=1 TO N
9022  FOR J=I TO N
9024  LET K=K+1
9026  LET A[K]=(D[I]+D[J])/2
9028  NEXT J
9030  NEXT I
9032  LET B=N*(N+1)/2
9034  LET I=1
9036  IF A[I] <= A[I+1] THEN 9050
9038  LET K=A[I]
9040  LET A[I]=A[I+1]
9042  LET A[I+1]=K
9044  IF I=1 THEN 9050
9046  LET I=I-1
9048  GOTO 9036
9050  LET I=I+1
9052  IF I<B THEN 9036
9054  LET C=C+1
9056  LET X=INT(C)
9058  LET R=C-X
9060  LET L=A[X]*(1-R)+A[X+1]*R
9062  LET X=B-X
9064  LET U=A[X+1]*(1-R)+A[X]*R
9066  PRINT L,U
9900  DATA 12,13.8,20.1,21,20.4,18.1,19,17.8
9901  DATA 20.3,19.2,21.5,19.7,20,18.2
9999  END 
