9000  REM *****BNKRSV*****BUSINESS PROGRAM
9005  REM BNKRSV**********VERSION #1 (7/31/69)*****BANK RESERVE CALCULATIONS
9010  REM
9015  PRINT "*  BANK RESERVE CALCULATIONS  *"
9020  PRINT 
9025  PRINT "THIS PROGRAM CALCULATES THE REQUIRED BANK RESERVE, AND THE RESERVE"
9030  PRINT "POSITION AT THE CLOSE OF A GIVEN BANK'S BUSINESS DAY."
9035  PRINT 
9040  PRINT 
9045  DIM A$[3]
9050  PRINT "PLEASE ENTER THE FOLLOWING BALANCES AT THE CLOSE OF BUSINESS YESTERDAY:"
9055  PRINT 
9060  PRINT "DEMAND DEPOSITS OF BANKS";
9065  INPUT C
9070  PRINT "U.S. GOVERNMENT DEMAND DEPOSITS";
9075  INPUT D
9080  PRINT "OTHER DEMAND DEPOSITS";
9085  INPUT E
9090  PRINT "CASH ITEMS IN PROCESS";
9095  INPUT F
9100  PRINT "DEMAND DEPOSITS DUE FROM BANKS";
9105  INPUT G
9110  PRINT "TIME DEPOSITS";
9115  INPUT H
9120  PRINT "CURRENCY AND COIN";
9125  INPUT H1
9130  LET S=(C+D+E-F-G)*.12+.03*H-H1
9135  LET S=INT(S+.5)
9140  PRINT 
9145  PRINT "*********************************************************************"
9150  PRINT 
9155  PRINT "          THE REQUIRED RESERVE IS EQUAL TO $";S
9160  PRINT 
9165  PRINT 
9170  PRINT "WOULD YOU LIKE TO CALCULATE THE STATEMENT OF RESERVE POSITION";
9175  INPUT A$
9180  PRINT 
9185  IF A$="NO" THEN 9635
9190  PRINT 
9195  PRINT "-----------------------------------------------------------------------"
9200  PRINT 
9205  PRINT "PLEASE ENTER THE FOLLOWING AMOUNTS:"
9210  PRINT 
9215  PRINT "FEDERAL RESERVE BANK BALANCE YESTERDAY";
9220  INPUT J
9225  PRINT "NUMBER OF DAYS REMAINING IN THE PERIOD";
9230  INPUT J1
9235  PRINT "CUMULATIVE EXCESS OR DEFICIENCY(-) AS OF YESTERDAY";
9240  INPUT J2
9245  PRINT "FEDERAL FUNDS RATE (IN DECIMALS)";
9250  INPUT K8
9255  PRINT "COLLECTED FLOAT TO BE CREDITED TODAY";
9260  INPUT K1
9265  PRINT "CASH LETTER";
9270  INPUT K
9275  PRINT "SECURITIES COLLECTED OR PURCHASED (-) BY THE FED";
9280  INPUT L
9285  PRINT "CASH SHIPPED OR ORDERED (-)";
9290  INPUT M
9295  PRINT "TRANSFERS IN OR OUT (-)";
9300  INPUT N
9305  PRINT "TREASURY TAX & LOAN CHARGE";
9310  INPUT O
9315  LET O=-(O)
9320  PRINT "OTHER CREDITS OR DEBITS(-)";
9325  INPUT P
9330  PRINT "FUTURE TRANSACTIONS -CREDITS OR DEBITS(-)";
9335  INPUT P9
9340  PRINT 
9345  PRINT 
9350  PRINT "                        ------------------"
9355  PRINT TAB(13);"*** STATEMENT OF RESERVE POSITION ***"
9360  PRINT TAB(11);J1;"DAYS REMAINING IN RESERVE PERIOD"
9365  PRINT 
9370  PRINT 
9375  PRINT "RESERVE BALANCE AT THE CLOSE YESTERDAY";TAB(60);J
9380  PRINT " ADD COLLECTED FLOAT TO BE CREDITED TODAY";TAB(60);K1
9385  PRINT TAB(60);"--------"
9390  PRINT TAB(30);"SUBTOTAL";TAB(60);J+K1
9395  PRINT "LESS CASH LETTER";TAB(60);K
9400  PRINT TAB(60);"--------"
9405  PRINT TAB(30)"SUBTOTAL";TAB(60);J+K1-K
9410  PRINT 
9415  PRINT "SECURITIES COLLECTED OR PURCHASED(-)";TAB(50);L
9420  PRINT "CASH SHIPPED OR ORDERED(-)";TAB(50);M
9425  PRINT "TRANSFERS IN OR OUT(-)";TAB(50);N
9430  PRINT "TREASURY TAX & LOAN CHARGE";TAB(50);O
9435  PRINT "OTHER CREDITS OR DEBITS(-)";TAB(50);P;
9440  LET B1=L+M+N+O+P
9445  PRINT TAB(60);B1
9450  PRINT TAB(60)"--------"
9455  LET B2=J+K1-K+B1
9460  PRINT "ESTIMATED RESERVE BALANCE AT CLOSE TODAY";TAB(60);B2
9465  PRINT " LESS REQUIRED RESERVE";TAB(60);S
9470  PRINT TAB(60);"--------"
9475  PRINT "INDICATED RESERVE EXCESS OR DEFICIENCY";TAB(60);B2-S
9480  PRINT "PRIOR CUMULATIVE EXCESS OR DEFICIENCY";TAB(60);J2
9485  LET B3=B2-S+J2
9490  PRINT TAB(60)"--------"
9495  PRINT "CUMMULATIVE EXCESS OR DEFICIENCY TO DATE";TAB(60);B3
9500  PRINT 
9505  PRINT 
9510  PRINT "CUM EXCESS OR DEF AFTER FUTURE TRANSACTIONS";TAB(60);
9515  PRINT B3+P9
9520  PRINT 
9525  PRINT "AVRG FOR D"'1"AYS REMAINING";TAB(60);(B3+P9)/J1
9530  PRINT 
9535  PRINT "                        ------------------"
9540  PRINT 
9545  PRINT "LEVEL OF","REQUIRED","EXCESS OR","CUMULATIVE","FED  FUNDS"
9550  PRINT "DEMAND DEP","RESERVE","DEFICIENCY","POSITION","VALUE"
9555  PRINT "----------","-------","----------","--------","-------"
9560  LET X7=C+D+E
9565  LET X8=INT((X7-X7*.1)/100+.5)*100
9570  LET X9=INT((X7+X7*.1)/100+.5)*100
9575  LET X5=INT((X8*.01)/100+.5)*100
9580  IF X5<10 THEN 9590
9585  GOTO 9595
9590  LET X5=100
9595  FOR I=X8 TO X9 STEP X5
9600  LET B4=(I-F-G)*.12+.03*H-H1
9605  LET B5=B2-B4
9610  LET B6=B5+B3
9615  LET B7=B6*(K8/360)*1000
9620  LET B7=INT(B7+.5)
9625  PRINT I,B4,B5,B6,B7
9630  NEXT I
9635  PRINT 
9640  PRINT "*********************************************************************"
9999  END 
