9000  REM *****STKINC*****BUSINESS PROGRAM
9005  REM STKINC**********VERSION #1 (7/31/69)*****STOCK INCENTIVE PROGRAM
9010  REM
9015  PRINT "*  STOCK INCENTIVE PROGRAM (MERGER)  *"
9020  PRINT 
9025  PRINT "THIS PROGRAM WILL PRINT A TABLE FOR STOCK INCENTIVE ESTIMATES, INCLUD-"
9030  PRINT "ING PROSPECTIVE PRICES AND GAINS, FOR A COMPANY CONSIDERING MERGING."
9035  PRINT 
9040  REM
9045  FILES STKFLE
9050  PRINT #1,1
9055  READ #1,1
9060  PRINT "WHAT IS YOUR PRICE/EARNING RATIO? (ANSWER MUST BE > 1)";
9065  INPUT T
9070  PRINT 
9075  PRINT #1;T
9080  PRINT "WHAT IS YOUR INTERNAL GROWTH RATE";
9085  INPUT I
9090  PRINT 
9095  IF I>1 THEN 9110
9100  PRINT "PLEASE ENTER A PERCENT > 1";
9105  GOTO 9085
9110  MAT A=ZER
9115  MAT B=ZER
9120  MAT C=ZER
9125  MAT D=ZER
9130  MAT E=ZER
9135  MAT F=ZER
9140  MAT G=ZER
9145  PRINT "WHAT IS YOUR COMPANY'S PRESENT BEFORE TAX EARNINGS";
9150  INPUT A[2]
9155  PRINT 
9160  LET B[2]=A[2]
9165  LET I1=I/100
9170  FOR X=3 TO 8
9175  LET B[X]=B[X-1]*(1+I1)
9180  NEXT X
9185  PRINT "---"
9190  PRINT 
9195  PRINT "WHAT IS THE INTERNAL GROWTH RATE OF THE COMPANY WITH WHICH YOU ARE CON-"
9200  PRINT "SIDERING MERGING";
9205  INPUT I8
9210  PRINT 
9215  IF I8>1 THEN 9230
9220  PRINT "ENTER A PERCENT > 1";
9225  GOTO 9205
9230  LET I9=I8/100
9235  PRINT "WHAT IS THIS COMPANY'S PRESENT BEFORE TAX EARNINGS";
9240  INPUT C[2]
9245  PRINT 
9250  FOR X=3 TO 8
9255  LET C[X]=C[X-1]*(1+I9)
9260  NEXT X
9265  PRINT "---"
9270  PRINT 
9275  PRINT "WHAT DO YOU EXPECT YOUR EXTERNAL GROWTH RATE TO BE AFTER MERGING";
9280  INPUT G1
9285  PRINT 
9290  IF G1>1 THEN 9305
9295  PRINT "ENTER A PERCENT . 1";
9300  GOTO 9290
9305  FOR X=3 TO 8
9310  PRINT #1;C[X]
9315  NEXT X
9320  FOR X=2 TO 8
9325  LET D[X]=C[X]+B[X]
9330  NEXT X
9335  PRINT "WHAT DO YOU EXPECT THE TOTAL NUMBER OF OUTSTANDING SHARES TO BE AFTER"
9340  PRINT "MERGING";
9345  INPUT S
9350  PRINT 
9355  PRINT "WHAT DO YOU EXPECT THE ANNUAL PERCENTAGE INCREASE IN THE NUMBER OF OUT-"
9360  PRINT "STANDING SHARES TO BE";
9365  INPUT S9
9370  IF S9>1 THEN 9385
9375  PRINT "ENTER A PERCENT > 1";
9380  GOTO 9365
9385  LET G2=G1/100
9390  LET S2=S9/100
9395  FOR X=3 TO 8
9400  LET E[X]=D[X]*(1+G2)
9405  LET F[X]=E[X]/S
9410  LET S=S*(1+S2)
9415  LET G[X]=F[X]*T
9420  NEXT X
9425  LET P=1
9430  PRINT 
9435  PRINT "************************************************************************"
9440  PRINT 
9445  PRINT TAB(24);1969;TAB(36);1970;TAB(48);1971;TAB(60);1972
9450  PRINT TAB(24);"-----------------------------------------------"
9455  PRINT 
9460  PRINT "CO. A BT EARNINGS"
9465  PRINT "(INT. GROWTH %";I;")";TAB(24);
9470  IF P <> 1 THEN 9485
9475  PRINT A[2];TAB(36);B[3];B[4];B[5]
9480  GOTO 9490
9485  PRINT B[6];TAB(36);B[7];TAB(48);B[8]
9490  PRINT 
9495  PRINT "CO. B BT EARNINGS"
9500  PRINT "(INT. GROWTH %";I8;")";TAB(24);
9505  IF P <> 1 THEN 9520
9510  PRINT C[2];TAB(36);C[3];TAB(48);C[4];TAB(60);C[5]
9515  GOTO 9525
9520  PRINT C[6];TAB(36);C[7];TAB(48);C[8]
9525  PRINT 
9530  PRINT "CONSOLIDATED EARNINGS"
9535  PRINT "(NO EXTERNAL GROWTH)";TAB(24);
9540  IF P <> 1 THEN 9555
9545  PRINT D[2];TAB(36);D[3];TAB(48);D[4];TAB(60);D[5]
9550  GOTO 9560
9555  PRINT D[6];TAB(36);D[7];TAB(48);D[8]
9560  PRINT 
9565  PRINT "EXT. GROWTH %";G1;TAB(24);
9570  IF P <> 1 THEN 9585
9575  PRINT TAB(36);E[3];TAB(48);E[4];TAB(60);E[5]
9580  GOTO 9590
9585  PRINT E[6];TAB(36);E[7];TAB(48);E[8]
9590  PRINT 
9595  PRINT "EARNINGS PER SHARE";TAB(24);
9600  IF P <> 1 THEN 9620
9605  PRINT TAB(36);F[3];TAB(48);F[4];TAB(60);F[5]
9610  PRINT #1;F[3];F[4]
9615  GOTO 9630
9620  PRINT F[6];TAB(36);F[7];TAB(48);F[8]
9625  PRINT #1;F[5];F[6];F[7];F[8]
9630  PRINT 
9635  PRINT "PRICE OF STOCK";TAB(24);
9640  IF P <> 1 THEN 9655
9645  PRINT TAB(36);G[3];TAB(48);G[4];TAB(60);G[5]
9650  GOTO 9660
9655  PRINT G[6];TAB(36);G[7];TAB(48);G[8]
9660  PRINT 
9665  PRINT 
9670  IF P <> 1 THEN 9690
9675  LET P=2
9680  PRINT TAB(24);1973;TAB(36);1974;TAB(48);1975
9685  GOTO 9450
9690  REM    2ND PART OF PROGRAM  -  CALC. EARNOUT SHARES AND GAIN, ETC.
9695  READ #1,1
9700  REM    READ P/E RATIO FROM FILE
9705  READ #1;F
9710  REM   DATA FROM THE FILE IS COMPANY B'S BEFORE TAX EARNINGS
9715  FOR X=1 TO 6
9720  READ #1;B[X]
9725  NEXT X
9730  MAT Z=ZER
9735  MAT N=ZER
9740  MAT M=ZER
9745  MAT Y=ZER
9750  MAT T=ZER
9755  PRINT 
9760  PRINT "                          ---------------"
9765  PRINT 
9770  PRINT "NOW PLEASE ENTER AN EARNOUT RATE";
9775  INPUT I
9780  PRINT 
9785  FOR X=1 TO 6
9790  READ #1;D
9795  LET Z[X]=D*F
9800  NEXT X
9805  FOR X=1 TO 6
9810  LET N[X]=(I*B[X])/Z[X]
9815  NEXT X
9820  PRINT "PLEASE ENTER THE NUMBER OF OUTSTANDING 'QUALIFIED' SHARES YOU EXPECT"
9825  PRINT "TO HAVE FOR EACH YEAR, AND THEIR PRICE:"
9830  LET N1=0
9835  FOR X=1 TO 6
9840  PRINT 1969+X;
9845  INPUT M[X],Y[X]
9850  LET N1=N1+N[X]
9855  LET T[X]=(Z[X]-Y[X])*M[X]+(N1*Z[X])
9860  NEXT X
9865  PRINT 
9870  PRINT 
9875  PRINT TAB(12);"EARNOUT";TAB(24);"QUALIFIED";TAB(36);"PURCHASE";
9880  PRINT TAB(48);"PROJECTED"
9885  PRINT "YEAR";TAB(12);"SHARES";TAB(24);"SHARES";TAB(36);"PRICE";
9890  PRINT TAB(48);"PRICE STOCK";TAB(62);"GAIN"
9895  PRINT "-------------------------------------------------------";
9900  PRINT "------------"
9905  PRINT 
9910  LET Y9=1970
9915  FOR X=1 TO 6
9920  PRINT Y9;
9925  IF X>4 THEN 9935
9930  PRINT TAB(12);N[X];
9935  PRINT TAB(24);M[X];TAB(36);Y[X];
9940  PRINT TAB(48);Z[X];TAB(60);T[X]
9945  PRINT 
9950  LET Y9=Y9+1
9955  NEXT X
9960  PRINT 
9965  PRINT 
9970  PRINT "|**********************************************************************"
9999  END 
