1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        AREA:   COMPUTER-AUGMENTED CALCULUS TOPICS (EULER'S
4  REM                METHOD)
5  REM        36668 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
100  PRINT "THIS PROGRAM COMPUTES APPROXIMATIONS TO THE AREA"
110  PRINT "BOUNDED BY THE X-AXIS AND THE GRAPH OF ANY POLYNOMIAL"
120  PRINT "FUNCTION OF DEGREE THREE OR LESS OVER AN INTERVAL OF"
130  PRINT "THE X-AXIS.  THE METHOD USED TO APPROXIMATE THE AREA"
140  PRINT "IS TO BUILD RECTANGLES WHOSE SUM WILL BE AN APPROXIMATION"
150  PRINT "TO THE AREA WE ARE TRYING TO FIND."
160  PRINT "THE POLYNOMIAL FUNCTION IS OF THE FORM"
170  PRINT 
180  PRINT "Y = A*X^3 + B*X^2 + C*X + D."
190  PRINT 
200  PRINT "YOU CAN GIVE ANY VALUES (INCLUDING 0) TO A,B,C, AND D."
210  PRINT "OK., ASSIGN NUMERICAL VALUES TO A, B, C, AND D."
220  PRINT "A=";
230  INPUT A
240  PRINT "B=";
250  INPUT B
260  PRINT "C=";
270  INPUT C
280  PRINT "D=";
290  INPUT D
300  PRINT "SELECT AN INTERVAL (R,S) ON THE X-AXIS"
310  PRINT "BY ASSIGNING VALUES TO R AND S."
320  PRINT "R=";
330  INPUT R
340  PRINT "S=";
350  INPUT S
360  IF R >= S THEN 650
370  PRINT "HOW MANY RECTANGLES DO YOU WANT TO BUILD ON [R,S]?"
380  PRINT "N=";
390  INPUT N
400  PRINT 
410  PRINT 
420  LET P=INT(N)
430  IF (N<1) OR (N <> P) OR (N>500) THEN 670
440  LET T=0
450  LET W=(S-R)/N
460  FOR X=R TO S-W STEP W
470  LET T=T+ABS(A*X^3+B*X^2+C*X+D)
480  NEXT X
490  LET T=T*W
500  PRINT "THE INTERVAL IS [";R;",";S;"]."
510  PRINT "THE NUMBER OF RECTANGLES IS ";N;"."
520  PRINT "THE FUNCTION IS "
530  PRINT A;"X^3 + ";B;"X^2 + ";C;"X + ";D;"."
540  PRINT 
550  PRINT "THE APPROXIMATION TO THE AREA IS *****";T;"*****"
560  PRINT 
570  PRINT 
580  PRINT "PLEASE SELECT OPTION 1, 2, 3, OR 4.  YOUR OPTION";
590  INPUT K
600  IF K=1 THEN 370
610  IF K=2 THEN 300
620  IF K=3 THEN 210
630  IF K=4 THEN 720
640  GOTO 700
650  PRINT "R MUST BE LESS THAN S. TRY AGAIN."
660  GOTO 300
670  PRINT "N MUST BE A POSITIVE WHOLE NUMBER"
680  PRINT "LESS THAN 500.  TRY AGAIN."
690  GOTO 370
700  PRINT "YOU GOOFED.  TAKE IT FROM THE TOP."
710  GOTO 580
720  END 
