10  REM**FLASH**C.A.I.**WORD RECALL DRILL**MAY 5, 1972
15  REM VOCAB, HP 36880A, 6/74
20  PRINT '10'10'10'10'10
30  R=I=0
40  DIM A$[72],E[100],B$[72]
50  IF TYP(0)=3 THEN 90
60  I=I+1
70  READ A$
80  GOTO 50
90  PRINT "WELCOME TO THE PROGRAM CALLED 'FLASH'.  THIS PROGRAM IS DESIGNED"
100  PRINT "TO HELP WITH THE RECALL OF WORDS.  A WORD WILL BE TYPED AND YOU"
110  PRINT "WILL BE CALLED UPON TO TYPE BACK THAT WORD."
120  PRINT '10'10
130  FOR J=1 TO I
140  E[J]=INT(I*RND(0)+1)
150  FOR K=1 TO J-1
160  IF E[J]=E[K] THEN 140
170  NEXT K
180  NEXT J
190  RESTORE 
200  PRINT "READY...."
210  PRINT 
220  FOR J=1 TO I
230  FOR K=1 TO E[J]
240  READ A$
250  NEXT K
260  RESTORE 
270  PRINT A$;'13;"XXXXXXXXXXXXXXX";'13;"GGGGGGGGGGGGGGG"
280  PRINT "WHAT WAS THE WORD";
290  INPUT B$
300  IF A$=B$ THEN 470
310  PRINT "INCORRECT ... THE CORRECT ANSWER IS: "A$
320  E[J]=-E[J]
330  A$=" "
340  NEXT J
350  PRINT "OUT OF "I" YOU GOT "R" CORRECT."
360  PRINT "THAT IS "R*100/I" PERCENT."
370  PRINT 
380  FOR C=1 TO I
390  IF E[C]>0 THEN 450
400  RESTORE 
410  FOR J=1 TO -E[C]
420  READ A$
430  NEXT J
440  PRINT "YOU GOT "A$" INCORRECT."
450  NEXT C
460  STOP 
470  PRINT "CORRECT"
480  R=R+1
490  GOTO 330
500  DATA "STATIONERY","AFFECT","PRINCIPAL","ELICIT","INGENIOUS"
510  DATA "VOCATION"
520  DATA "ORDINANCE","IRRITATING","EXCEEDINGLY","COUNSEL","UNINTERESTED"
530  DATA "CONTEMPTIBLE","IMMIGRANT","IMPLIED","ADVISED","VENAL","CREDIBLE","PRACTICABLE"
540  DATA "FEASIBLE","COMPLEMENTS"
9000  END 
