1  REM ****  HP BASIC PROGRAM LIBRARY  ******************************
2  REM
3  REM       GMCRO2: FISCAL POLICY GAME
4  REM
5  REM       36519 REV A, PART 2 OF 2
6  REM
7  REM ****  CONTRIBUTED PROGRAM  ***********************************
10  REM          * * * MACROECONOMIC POLICY GAME #2 * * *
20  REM          (KEITH LUMSDEN, STANFORD G.S.B.,AUG 1971)
100  PRINT "MCRO2 MAY REQUIRE AN HOUR OR MORE TO PLAY CAREFULLY."
105  PRINT "IF YOU THINK THAT YOU MAY POSSIBLY WISH TO PLAY IT"
110  PRINT "IN MORE THAN ONE SITTING, OR MAY WISH TO STOP TO THINK"
115  PRINT "BEFORE CONTINUING, YOU SHOULD CREATE A FILE TO STORE"
120  PRINT "THE DATA GENERATED BY YOUR ECONOMY."
125  PRINT 
130  PRINT "DO YOU WANT THE FLEXIBILITY TO STOP THE GAME AND RETURN"
135  PRINT "LATER   ";
140  INPUT M$
145  IF M$="NO" THEN 255
150  PRINT 
155  PRINT "WHEN THE PROGRAM STOPS, TYPE"
156  PRINT 
160  PRINT "200 FILES DATA2"
165  PRINT "OPEN-DATA2,1"
170  PRINT "RUN-200"
171  PRINT 
175  PRINT "THE PROGRAM WILL NOW STOP TO ALLOW YOU TO TYPE IN THESE LINES."
180  PRINT "TYPE IN THE LINES AFTER THE COMPUTER PRINTS 'DONE'."
185  PRINT 
190  STOP 
205  PRINT "IF YOU DESIRE TO STOP THIS PROGRAM DURING EXECUTION, YOU MAY"
210  PRINT "DO SO BY TYPING '9999' WHEN THE CHANGE IN G IS REQUESTED."
215  PRINT "REMEMBER TO TYPE IN THE CHANGE IN T ALSO.  YOU MAY THEN"
220  PRINT "LOGOFF AND RESUME MCRO2 IN THE YEAR THAT YOU STOP."
225  PRINT "INSTRUCTIONS FOR RESTARTING WILL BE GIVEN WHEN YOU STOP."
245  PRINT 
250  PRINT "MCRO2 DEALS WITH THEORIES OF AGGREGATE CONSUMPTION. THE";
255  PRINT "MODEL GENERATES QUARTERLY OBSERVATIONS, BUT YOU CAN CHANGE"
260  PRINT "G AND T ONLY ONCE A YEAR. WHEN YOU ARE REQUESTED TO DO SO ";
265  PRINT "TYPE IN THE VALUES FOR CHANGES IN G AND T. IF THERE IS"
270  PRINT "NO CHANGE TYPE A ZERO. NOTE THAT THE CHANGES IN G AND T"
275  PRINT "ARE TO BE ENTERED ON THE SAME LINE SEPARATED BY A COMMA."
310  PRINT 
315  PRINT "YOUR OBJECTIVES IN THE NEXT 15 YEARS ARE TO KEEP Y AS CLOSE";
320  PRINT "TO Q AS POSSIBLE AND TO DETERMINE FROM THE ECONOMY'S"
325  PRINT "PERFORMANCE THE PARAMETERS OF THE CONSUMPTION FUNCTION. YOU"
330  PRINT "BEGIN THE FIRST YEAR WITH A SCORE OF 5000. EACH QUARTER"
335  PRINT "YOU LOSE THE ABSOLUTE VALUE OF THE DIFFERENCE ";
340  PRINT "BETWEEN Y AND Q."
345  DATA 600,520,55,25,50,550,610,5000,1,0
346  DIM M$[5]
350  DIM N$[26]
355  PRINT LIN(2)
360  PRINT "TYPE YOUR NAME  -";
365  INPUT N$
370  READ Y,C,I,G,T,D,Q,W,X,N
375  GOTO 1240
520  PRINT "ENTER CHANGES IN G,T -";
540  INPUT Z3,Z2
550  IF Z3=9999 THEN 2000
600  PRINT "CHECK YOUR VALUES. CHANGES ? (1=YES, 0=NO) ??";
640  INPUT E9
660  IF E9=1 THEN 520
680  IF N <> 8 THEN 720
700  IF Z3<10 THEN 3600
720  IF N <> 48 THEN 760
740  IF Z2>-10 THEN 3600
760  IF Z2<-T THEN 3600
780  IF Z3<-G THEN 3600
800  IF X=1 THEN 860
820  IF X=2 THEN 940
840  IF X=3 THEN 1020
860  LET Y=250-9*(T+Z2)+10*(I+G+Z3)
880  LET D=Y-T-Z2
900  LET C=25+.9*D
920  GOTO 1080
940  LET C=25+.9*D1
960  LET Y=C+I+G+Z3
980  LET D=Y-T-Z2
1000  GOTO 1080
1020  LET Y=(-.4625*(T+Z2)+.5*C+I+G+Z3)/.5375
1040  LET D=Y-T-Z2
1060  LET C=.4625*D+.5*C
1080  IF D<0 THEN 3600
1100  LET T=T+Z2
1120  LET G=G+Z3
1140  LET N=N+1
1160  LET Q=Q*1.01
1180  LET W=W-ABS(Q-Y)
1200  LET Z2=Z3=0
1220  LET D1=D
1240  PRINT 
1260  PRINT N$,"GNP ACCOUNTS    QUARTER";N
1280  PRINT "Q="Q,"Y="Y,"C="C,"I="I
1290  PRINT "D="D,"G="G,"T="T,"SCORE="W
1300  IF N/4 <> INT(N/4) THEN 800
1320  PRINT 
1340  PRINT 
1360  PRINT 
1380  IF N <> 0 THEN 1460
1400  PRINT "CONSUMERS BEHAVIOR IS NOW REPRESENTED BY A FUNCTION OF THE";
1420  PRINT "FORM:  C(T)=A+B*D(T) WHERE T=NUMBER OF THE QUARTER."
1440  GOTO 520
1460  IF N <> 8 THEN 1540
1480  PRINT "WAR HAS BROKEN OUT IN THE MIDDLE EAST. DEFENSE NEEDS REQUIRE";
1500  PRINT "THAT YOU RAISE G NEXT YEAR BY AT LEAST 10."
1520  GOTO 520
1540  IF N <> 20 THEN 1760
1560  PRINT "TYPE YOUR ESTIMATES OF A AND B IN THE CONSUMPTION FUNCTION: ";
1580  INPUT X1,X2
1600  PRINT "WHAT IS THE VALUE OF THE G MULTIPLIER? ";
1620  INPUT X1
1640  PRINT "THANK YOU. ACTUALLY A=25,B=.9 AND THE G MULTIPLIER=10."
1660  PRINT 
1680  PRINT "CONSUMER BEHAVIOR CHANGES. IT CAN NOW BE REPRESENTED BY A";
1700  PRINT "FUNCTION OF THE FORM: C(T)=A+B*D(T-1)"
1720  LET X=2
1740  GOTO 520
1760  IF N <> 28 THEN 1860
1780  PRINT "AN INVESTMENT SURVEY PREDICTS A DROP OF INVESTMENT TO 50 ";
1800  PRINT "NEXT QUARTER."
1820  LET I=50
1840  GOTO 520
1860  IF N <> 40 THEN 3260
1880  PRINT "TYPE YOUR ESTIMATES OF A AND B IN THE CONSUMPTION FUNCTION. ";
1900  INPUT X1,X2
1910  PRINT 
1920  PRINT "NOTICE THAT THE SIZE OF MULTIPLIERS NOW DEPENDS ON THE LENGTH ";
1940  PRINT "OF THE TIME PERIOD UNDER CONSIDERATION. WHAT IS YOUR ESTIMATE OF";
1960  PRINT "1) THE SIZE OF THE ONE-QUARTER INVESTMENT MULTIPLIER";
1980  INPUT X1
1990  GOTO 3000
2000  REM THIS STORES THE DATA FOR USE AT AT LATER TIME WHEN RESTARTING
2001  REM THE PROGRAM
2011  READ #1,1
2020  PRINT #1;N$
2030  PRINT #1;Y,C,I,G,T,D,Q,W,X,N
2040  PRINT "YOUR DATA HAS BEEN STORED IN A FILE DESIGNATED DATA2"
2041  PRINT "TO RESTART THE GAME, CALL UP MCRO2 AND TYPE"
2042  PRINT 
2043  PRINT "2510 FILES DATA2"
2044  PRINT "RUN-2500"
2050  STOP 
2499  STOP 
2500  REM THIS RESTARTS THE PROGRAM WHERE IT WAS PREVIOUSLY TERMINATED"
2520  READ #1,1
2525  READ #1;N$
2530  READ #1;Y,C,I,G,T,D,Q,W,X,N
2550  GOTO 1220
3000  PRINT "2) THE SIZE OF THE FOUR-QUARTER INVESTMENT MULTIPLIER";
3020  INPUT X2
3040  PRINT "3) THE SIZE OF THE EQUILIBRIUM INVESTMENT MULTIPLIER"
3060  PRINT "   (THAT IS, AFTER AN INFINITITELY LARGE NUMBER OF"
3080  PRINT "   QUARTERS)";
3100  INPUT X1
3110  PRINT 
3120  PRINT "THANK YOU. THE ACTUAL VALUES OF A AND B WERE 25,.9. ";
3140  PRINT "THE INVESTMENT MULTIPLIERS WERE 1,3.4, AND 10 RESPECTIVELY."
3160  PRINT 
3180  PRINT "CONSUMER BEHAVIOR CHANGES AGAIN. IT CAN NOW BE REPRESENTED";
3200  PRINT "BY C(T)=A*D(T)+B*C(T-1)"
3220  LET X=3
3240  GOTO 520
3260  IF N <> 48 THEN 3340
3280  PRINT "THE TAXPAYERS LEAGUE, A STRONG LOBBY, PERSUADES CONGRESS ";
3300  PRINT "THAT TAXES SHOULD BE CUT BY 10 NEXT YEAR. YOU MUST COMPLY."
3320  GOTO 520
3340  IF N <> 60 THEN 520
3360  PRINT "TYPE YOUR ESTIMATES OF A AND B IN THE CONSUMPTION FUNCTION. ";
3380  INPUT X1,X2
3400  PRINT "TYPE YOUR ESTIMATES OF THE ONE-QUARTER, FOUR-QUARTER AND ";
3420  PRINT "EQUILIBRIUM TAX MULTIPLIERS. ";
3440  INPUT X,X1,X2
3460  PRINT "THANK YOU. THE ACTUAL VALUES OF A AND B WERE .4625,.5. ";
3480  PRINT "THE TAX MULTIPLIERS WERE APPROXIMATELY -.86,-3.10, AND -12.33."
3500  PRINT 
3520  PRINT "YOUR FINAL SCORE FOR KEEPING Y CLOSE TO Q IS"W
3540  PRINT 
3560  PRINT "THIS ENDS MCRO2. LOGOFF."
3580  STOP 
3600  PRINT 
3620  PRINT "THE CHANGES YOU MADE ARE NOT PERMISSIBLE. ";
3640  PRINT "CHECK YOUR WORK AND RE-ENTER."
3660  GOTO 540
9999  END 
