10  REM ****  HP TIME-SHARED BASIC PROGRAM LIBRARY  ********************
20  REM
30  REM              PHOTEL:  PHOTOELECTRIC EFFECT
40  REM
50  REM              36317 (A833)  REV A -- 10/71
60  REM
70  REM ****  CONTRIBUTED PROGRAM  *************************************
80  REM A.C. CAGGIANO;PATCHOGUE H.S. PHYSICS; 7-16-68
90  REM PHOTEL - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM  REVISED BY C.LOSIK  8-21-70 
110  REM  A IS WHICH METAL, L IS THE PRINTED WAVELENGTH,
120  REM  N ARE THE CURRENTS, K IS INTENSITY, F IS INCREASING INTENSITY 
130  PRINT " ","THE PHOTOELECTRIC EFFECT"
140  PRINT 
150  PRINT 
160  PRINT "WHEN LIGHT OF SHORT WAVELENGTH FALLS ON A METAL SURFACE,"
170  PRINT "ELECTRONS ARE EJECTED FROM THE METAL. ACCORDING TO THE"
180  PRINT "DESCRIPTION OF THIS PHENOMENA BY EINSTEIN, THERE IS A"
190  PRINT "MAXIMUM WAVELENGTH FOR EACH METAL ABOVE WHICH NO ELECTRONS"
200  PRINT "ARE EMITTED. IN THIS EXPERIMENT WE WILL DETERMINE THE"
210  PRINT "CRITICAL WAVELENGTH AT WHICH THIS OCCURS."
220  PRINT 
230  PRINT "THE METAL SELECTED WILL BE PLACED IN A VACUUM WHERE IT"
240  PRINT "WILL BE BOMBARDED BY SOFT X-RAYS. THE NUMBER OF ELECTRONS"
250  PRINT "EJECTED WILL BE COLLECTED AND COUNTED WITH AN AMMETER."
260  PRINT "(NOTE:THE CURRENT IS RELATED TO THE NUMBER OF ELECTRONS"
270  PRINT "EMITTED BY THE METAL)."
280  PRINT 
290  PRINT "SELECT ONE OF THE METALS LISTED BY TYPING ITS NUMBER."
300  PRINT 
310  PRINT " ","1) SILVER"
320  PRINT " ","2) BISMUTH"
330  PRINT " ","3) CADMIUM"
340  PRINT " ","4) LEAD"
350  PRINT " ","5) PLATINUM"
360  PRINT 
370  INPUT A
380  IF A>1 THEN 400
390  LET V0=.308
400  IF A <> 2 THEN 420
410  LET V0=.338
420  IF A <> 3 THEN 440
430  LET V0=.318
440  IF A <> 4 THEN 460
450  LET V0=.34
460  IF A<5 THEN 480
470  LET V0=.385
480  LET K=INT(1+2*RND(0))
490  PRINT 
500  PRINT " ","MEASURED CURRENT (MICROAMPERES)"
510  PRINT "WAVELENGTH","TRIAL 1","TRIAL 2","TRIAL 3"
520  FOR L=.42 TO .25 STEP -.02
530  LET M=INT(1000/L)
540  PRINT M,
550  FOR J=1 TO 3
560  IF L>V0 THEN 590
570  LET I=SQR(INT(25*RND(0)))
580  GOTO 600
590  LET I=SQR(K*K*100+INT(35*RND(0)))
600  LET N=INT(10*I+.5)/10
610  PRINT N,
620  NEXT J
630  PRINT 
640  NEXT L
650  PRINT 
660  PRINT "DO YOU WISH TO INCREASE THE LIGHT INTENSITY?"
670  PRINT "(1=YES, 0=NO) : ";
680  INPUT G
690  IF G=0 THEN 770
700  IF G <> 1 THEN 670
710  PRINT 
720  PRINT "BY WHAT FACTOR? (SELECT FACTOR BETWEEN 1 AND 10)."
730  INPUT F
740  IF ABS(F-5.5)>4.5 THEN 720
750  LET K=K*F
760  GOTO 490
770  PRINT 
780  PRINT "DO YOU WISH TO TRY ANOTHER METAL (1=YES, 0=NO) : ";
790  INPUT H
800  IF H=1 THEN 290
810  IF H <> 0 THEN 780
820  PRINT 
830  PRINT "NOW BY PLOTTING THE WAVELENGTH VS. THE MEASURED CURRENT,"
840  PRINT "(AVERAGE OF THREE TRIALS), THE PHOTOELECTRIC EFFECT AS"
850  PRINT "DESCRIBED BY EINSTEIN WILL BECOME APPARENT."
860  PRINT 
870  PRINT "THANK YOU."
880  END 
