1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        SQRT:   FINDS SQUARE ROOT
4  REM
5  REM        36627 REV  A   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
50  REM SQRT - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM  T. BURNS, JOHN GLENN HS,  8-6-69 
110  REM  REVISED BY C.LOSIK   8-27-70 
120  REM  A=LOWER LIMIT, B=UPPER LIMIT, Z=STEP IN INTERVAL 
121  REM  E IS THE ACCURACY YOU DESIRE 
125  LET E=.0001
130  PRINT "PROGRAM FINDS SQUARE ROOT OF ANY POSITIVE NUMBER"
140  PRINT "BY 'PINCHING' IT WITHIN A SMALLER AND SMALLER INTERVAL."
150  PRINT 
160  PRINT 
170  PRINT "WHAT IS THE NUMBER WHOSE SQUARE ROOT YOU SEEK";
180  INPUT Z
185  PRINT 
190  IF Z>0 THEN 220
200  PRINT "YOUR NUMBER MUST BE POSITIVE !!!"
210  GOTO 160
220  PRINT 
230  PRINT "LOWER LIMIT"," "," ","UPPER LIMIT"
235  PRINT "----- -----"," "," ","----- -----"
240  LET A=0
250  LET B=Z
260  LET S=(B-A)/10
270  PRINT A,"< SQ.RT. OF"Z"<",B
275  IF ABS(A*B-Z)<E THEN 360
280  FOR I=A TO B STEP S
290  IF Z<I*I THEN 310
300  NEXT I
301  LET B=B*10
302  GOTO 260
310  LET B=I
320  LET A=I-S
350  GOTO 260
360  PRINT 
370  PRINT "APPROXIMATION NOW CORRECT TO AN ACCURACY OF"E
380  PRINT "YOU MAY USE EITHER"A"OR"B"AS THE SQUARE ROOT OF"Z
390  PRINT 
400  PRINT 
410  PRINT "WANT TO TRY ANOTHER NUMBER (1=YES, 0=NO) : ";
420  INPUT Z
430  IF Z=1 THEN 150
440  IF Z <> 0 THEN 400
450  END 
