1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        STOICH:   MASS VOLUME
4  REM
5  REM        36618 REV  A   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
50  REM STOICH - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM HARRY DORFMAN, JOHN GLENN H.S.7/23/68  ( REV.7/9/69 )
105  REM  REVISED BY C.LOSIK   7-22-70
106  REM  DIFFERENT VARIABLES ARE USED IN EACH PROBLEM
107  REM  THEIR MEANING MAY BE DETERMINED BY LOOKING AT EACH SECTION
108  REM  OF THE PROGRAM (VARS. CORRESPOND WITH INPUTS AND PRINTS)
110  REM THIS PROGRAM IS DESIGNED TO SOLVE MASS-MASS,MASS-VOLUME, 
120  REM AND VOLUME-VOLUME PROBLEMS.  
123  REM
125  REM  EACH INPUT HAS A DIFFERENT LETTER CORRESPONDING TO
126  REM  THE INFORMATION IN THE PRINTED QUESTION.
130  REM
140  PRINT " DO YOU WISH TO SKIP THE INSTRUCTIONS? 1 FOR YES ,0 FOR NO";
150  INPUT Z
160  IF Z=1 THEN 320
162  IF Z <> 0 THEN 130
170  PRINT "THIS PROGRAM IS DESIGNED TO SOLVE:"
180  PRINT "       1. MASS-MASS PROBLEMS"
190  PRINT "       2. MASS-VOLUME PROBLEMS"
200  PRINT "       3. VOLUME-VOLUME PROBLEMS"
210  PRINT 
220  PRINT "SOME GENERAL INSTRUCTIONS FOR USING THE PROGRAM WILL"
230  PRINT "BE HELPFUL AT THIS TIME."
240  PRINT "     1. IF TWO PIECES OF DATA ARE REQUESTED, BE SURE TO"
250  PRINT "        GIVE THEM IN THE ORDER REQUESTED AND SEPARATE"
260  PRINT "        THEM WITH A COMMA."
270  PRINT "     2. THE BALANCED EQUATION IS THE FIRST THING"
280  PRINT "        NEEDED WITH EACH TYPE OF PROBLEM SO HAVE IT PREPARED."
290  PRINT "     3. THE FORMULA WEIGHTS ARE NEEDED NEXT SO HAVE THEM"
300  PRINT "        PREPARED."
310  PRINT 
320  PRINT 
330  PRINT "PICK THE TYPE OF CALCULATION YOU DESIRE BY ANSWERING THE"
340  PRINT "FOLLOWING QUESTION WITH A 1,2, OR 3:"
350  PRINT "             1 FOR MASS-MASS CALCULATIONS"
360  PRINT "             2 FOR MASS-VOLUME CALCULATIONS"
370  PRINT "             3 FOR VOLUME-VOLUME CALCULATIONS"
380  PRINT 
390  PRINT "WHAT IS THE NUMBER OF YOUR CHOICE";
400  INPUT A
410  PRINT " ","***************"
420  PRINT 
430  IF A=1 THEN 470
440  IF A=2 THEN 830
450  IF A=3 THEN 1150
455  PRINT "USE 1, 2, OR 3.  TRY AGAIN."
460  GOTO 390
470  PRINT " PROVIDE THE FOLLOWING DATA FOR THIS MASS-MASS PROBLEM:"
480  PRINT 
490  PRINT "HOW MANY MOLES OF KNOWN COMPOUND AND UNKNOWN COMPOUND"
500  PRINT "ARE SHOWN IN THE BALANCED CHEMICAL EQUATION";
510  INPUT B,C
520  PRINT "WHAT IS THE FORMULA WEIGHT OF THE KNOWN COMPOUND"
530  PRINT " AND THE UNKNOWN COMPOUND ";
540  INPUT D,E
550  PRINT " WHAT MASS, IN GRAMS, OF THE KNOWN COMPOUND IS INVOLVED"
560  PRINT " IN THE CHEMICAL REACTION?  IF THIS INFORMATION IS AVAILABLE"
570  PRINT " IN MOLES ANSWER ZERO (0) AND WAIT FOR THE NEXT QUESTION";
580  INPUT F
590  IF F=0 THEN 620
600  LET G=F/D
610  GOTO 650
620  PRINT " HOW MANY MOLES OF KNOWN COMPOUND WERE INVOLVED IN"
630  PRINT " THE CHEMICAL REACTION";
640  INPUT G
650  LET H=(C/B)*G
660  PRINT " ANSWERS: .................."H" MOLES OF UNKN. CPD."
670  LET J=H*E
680  PRINT "         .................."J" GRAMS OF UNKN. CPD."
690  PRINT 
700  PRINT " ","***************"
710  PRINT 
720  PRINT "DO YOU WISH TO SOLVE ANOTHER PROBLEM?  ANSWER 1 FOR M-M,"
730  PRINT " 2 FOR M-V, 3 FOR V-V, AND ZERO (0) TO END THE PROGRAM.";
740  INPUT Y
745  PRINT 
750  PRINT " ","***************"
760  PRINT 
770  IF Y=1 THEN 470
780  IF Y=2 THEN 830
790  IF Y=3 THEN 1150
800  IF Y <> 0 THEN 810
805  STOP 
810  PRINT " YOU MUST USE 0,1,2, OR 3.  TRY AGAIN."
820  GOTO 720
830  PRINT " PROVIDE THE FOLLOWING DATA FOR THIS MASS-VOLUME PROBLEM:"
840  PRINT 
850  PRINT " HOW MANY MOLES OF KNOWN COMPOUND AND UNKNOWN COMPOUND"
860  PRINT " ARE SHOWN IN THE BALANCED EQUATION";
870  INPUT K,L
880  PRINT "WHAT IS THE FORMULA WEIGHT OF THE KNOWN COMPOUND AND THE"
890  PRINT " UNKNOWN COMPOUND";
900  INPUT M,N
910  PRINT " WHAT MASS, IN GRAMS, OF THE KNOWN COMPOUND IS INVOLVED"
920  PRINT " IN THE CHEMICAL REACTION? IF ONLY VOLUME IS KNOWN"
930  PRINT " ANSWER ZERO (0) AND WAIT FOR THE NEXT QUESTION";
940  INPUT P
950  IF P=0 THEN 1040
960  LET R=(L/K)*(P/M)
970  PRINT "ANSWERS: ............................"R"MOLES OF UNKN. GAS"
980  LET S=R*22.4
990  PRINT "         ............................"S" LITERS OF UNKN. GAS"
1030  GOTO 690
1040  PRINT " WHAT IS THE VOLUME, IN LITERS, OF THE KNOWN GAS"
1050  PRINT "INVOLVED IN THE CHEMICAL REACTION? (VOLUME MUST BE AT STP)";
1060  INPUT Q
1070  LET T=(Q/22.4)*(L/K)
1080  PRINT " ANSWERS:...................."T" MOLES OF UNKN. CPD."
1090  LET U=T*N
1100  PRINT "         ...................."U" GRAMS OF UNKN. CPD."
1140  GOTO 690
1150  PRINT "PROVIDE THE FOLLOWING DATA FOR THIS VOLUME-VOLUME PROBLEM:"
1160  PRINT 
1170  PRINT "HOW MANY MOLES KNOWN GAS AND UNKNOWN GAS ARE SHOWN"
1180  PRINT " IN THE BALANCED EQUATION";
1190  INPUT U,V
1200  PRINT " WHAT IS THE VOLUME IN LITERS OF THE KNOWN GAS INVOLVED"
1210  PRINT " IN THE CHEMICAL REACTION? (VOLUME MUST BE AT STP.)";
1220  INPUT W
1230  LET X=(V/U)*W
1240  PRINT "ANSWER: ............................."X"LITERS OF UNKN. GAS"
1280  GOTO 690
1300  END 
