10  REM *** THE DANGLING STRING ***
20  REM *** WRITTEN BY DAVE KAUFMAN, AUGUST 1973 ***
30  REM *** COPYRIGHT, PEOPLE'S COMPUTER CENTER ***
40  REM *** 1921 MENALTO AVE., MENLO PARK, CA. ***
50  REM G IS THE # OF THIS GAME
60  G=1
70  PRINT "WELCOME TO ... THE DANGLING STRING"'7'7'7
80  PRINT 
90  PRINT "HOW MANY STARS DO YOU WANT";
100  INPUT S
110  S=ABS(INT(S) MAX 1)
120  PRINT 
130  PRINT "HOW WILD";
140  IF G>1 THEN 200
150  PRINT "?"
160  PRINT "  4=VERY WILD"
170  PRINT "  3=PRETTY WILD"
180  PRINT "  2=A LITTLE WILD"
190  PRINT "  1=A TINY BIT WILD"
200  INPUT W
210  W=ABS(INT(W))
220  IF W>0 THEN 250
230  W=1
240  GOTO 270
250  IF W <= 4 THEN 270
260  W=4
270  REM GET FIRST POSITION
280  PRINT 
290  PRINT "WHERE WILL THE STRING START";
300  IF G>1 THEN 350
310  PRINT "?"
320  PRINT "1        10        20        30"
330  PRINT "I        I         I         I"
340  PRINT 
350  INPUT X
360  X=ABS(INT(X))
370  X=((X-1) MAX 0) MIN 32
380  PRINT TAB(X);"*"
390  REM FIND THE FIRST DISPLACEMENT
400  D=SGN(32*RND(0)-X+1)
410  REM NOW LOOP FOR EACH STAR
420  FOR I=2 TO S
430  D=D+SGN(32*RND(0)-X+1)
440  IF W >= ABS(D) THEN 460
450  D=W*SGN(D)
460  REM FIND NEXT POINT
470  X=X+D
480  IF X>0 THEN 500
490  X=1
500  PRINT TAB(X);"*"
510  NEXT I
520  PRINT 
530  PRINT "THAT'S ALL, FOLKS!"
540  PRINT 
550  G=G+1
560  PRINT '7'7'7"HERE WE GO AGAIN ..."
570  GOTO 80
580  END 
