10  REM ***** DATA CAN BE ENTERED IN ANY ORDER *** EXCEPT *****
20  REM ***** THE NUMBER OF SCORES MUST BE FIRST *****
30  REM ***** MODIFIED BY DR. L. WINRICH AND E. SCHROEDER *****
40  REM ***** UNIVERSITY WISCONSIN - LA CROSSE ***** DEC. 1973 *****
50  REM HP CONTRIBUTED LIBRARY, 2/75
120  REM
130  DIM X[100],D[100],Z[100],T[100]
140  LET X=0
150  READ N
160  FOR I=1 TO N
170  READ X[I]
180  LET X=X+X[I]
190  NEXT I
200  F=0
210  K=N-1
220  FOR I=1 TO K
230  IF X[I] >= X[I+1] THEN 280
240  F=100
250  T1=X[I]
260  X[I]=X[I+1]
270  X[I+1]=T1
280  NEXT I
290  IF F#0 THEN 200
300  LET M=X/N
310  PRINT "MEAN = ";M
320  LET D=0
330  FOR I=1 TO N
340  LET D[I]=X[I]-M
350  LET D=D+D[I]^2
360  NEXT I
370  LET S=SQR(D/N)
380  PRINT "STANDARD DEVIATION = ";S
390  FOR I=1 TO N
400  LET Z[I]=D[I]/S
410  LET T[I]=10*D[I]/S+50
420  NEXT I
430  PRINT 
440  PRINT "SCORE","DEVIATION","Z-SCORE","T-SCORE"
450  PRINT "-----","---------","-------","-------"
460  FOR I=1 TO N
470  PRINT  USING 480;X[I],D[I],Z[I],T[I]
480  IMAGE XDDD,12XDDD.D,8XDDD.DD,10XDDD.DD
490  NEXT I
500  DATA 33
510  DATA 62,74,61,64,44,37,58,22,99,47,73,69,85,54,87,34,49
520  DATA 48,62,57,75,29,64,89,59,44,64,66,39,99,67,89,70
530  END 
