         SYSTEM   SIG7
         SYSTEM   BPM
         REF      F:FILE,M:C
ABORT    COM,12,20,12,20    X'226',AF(1),X'680',ABORT
BFILE    RES      21                BUFFER FOR FILE RECORDS
BFCR     RES      20                BUFFER FOR CR RECORDS
START    M:OPEN   F:FILE,(IN)
         LI,2     X'40'
LP1      LW,1     =(80+3+80)**24+BA(BFILE)+1
         MBS,0    =X'40000000'      BLANK FILE BUFFER
         M:READ   F:FILE,(BUF,BFILE),(SIZE,80),(ABN,ABF),(BTD,1)
RDCR     M:READ   M:C,(BUF,BFCR),(SIZE,80),(ABN,ABC)
         LH,1     F:FILE+4          L/ARS
         SLS,1    -1                G/ARS
         CB,2     BFILE,1           C/X'40' W/LAST CHAR
         BLE      %+2               BLE; NOT CNTRL CHAR
         STB,2    BFILE,1           REPLACE CNTRL CHAR W/BLANK
         LW,3     =80**24+BA(BFILE)+1
         CBS,3    BA(BFCR)-BA(BFILE)-1
         BE       LP1
         ABORT    TC1
ABF      LB,4     10                L/ABN CODE
         CI,4     7                 C/ABN CODE W/7
         BE       RDCR              BE; IGNORE LOST DATA COND
         CI,4     6                 C/ABN CODE W/6; EOF
         BNE      BADF              BNE; ABORT
         M:READ   M:C,(ABN,ABF20)   TRY ANOTHER READ TO M:C
         ABORT    TC7               READ SUCCESSFUL, UNEQUAL FILES
ABF20    M:PRINT  (MESS,TC8)        ASSUME EOF ON M:C
         M:EXIT                     EXIT
ABORT    M:PRINT  (MESS,*6)         PRINT ERROR MESS
         M:PRINT  (MESS,TC3)
         M:WRITE  M:LL,(BUF,BFILE),(BTD,1),(SIZE,80)
         M:PRINT  (MESS,TC4)
         M:WRITE  M:LL,(BUF,BFCR),(SIZE,80),(BTD,0)
         M:XXX
BADF     ABORT    TC5
ABC      LB,4     10
         CI,4     5                 C/ABN CODE W/5
         BE       EOFC              BE; PREMATURE EOF ON M:C
         CI,4     6                 C/ABN CODE W/6
         BE       EOFC              BE; PREMATURE EOF ON M:C
         ABORT    TC6
EOFC     ABORT    TC2
TC1      TEXTC    'RECORD MISSMATCH'
TC2      TEXTC    'MORE RECORDS IN FILE THAN CR'
TC3      TEXTC    'LAST FILE RECORD:'
TC4      TEXTC    'LAST CARD:'
TC5      TEXTC    'ABN ON F:FILE'
TC6      TEXTC    'ABN ON M:C'
TC7      TEXTC    'MORE RECORDS IN CR THAN IN FILE'
TC8      TEXTC    'FILE AND DECK COMPARES OK'
         END      START
